原因是 tuple 以及 each fields 元组内部有 same delimiter ( ',' ). 在这种情况下，pig将解析输入并在模式转换中失败。
您可以在控制台中看到以下日志

"Unable to interpret the value in field being converted to type tuple, caught ParseException <Unexpect end of tuple> field discarded"

来解决这个问题
您需要更改元组分隔符 ',' 去做些不同的事。在下面的例子中，我使用了 '#' 作为分隔符而不是 ',' . 可以使用（'，'以外的任何分隔符
输入文件有两个元组，但在加载模式中只定义了一个元组，因此还需要定义另一个元组。
示例：
输入

(Eric,Ack,27,M)#(Jeremy,Ross,29,F)
(Jenny,Dicken,27,F)#(Vijay,Sampath,40,M)
(Angs,Dicken,28,M)#(Venu,Rao,28,M)
(Mahima,Mohanty,29,F)#(Kenny,Oath,28,M)

Pig手稿：

tuple_record = LOAD '~/Documents/Pig_Tuple.txt' USING PigStorage('#') AS (details:tuple(firstname:chararray,lastname:chararray,age:int,sex:chararray), details1:tuple(firstname1:chararray,lastname1:chararray,age1:int,sex1:chararray));
DUMP tuple_record;

输出：

((Eric,Ack,27,M),(Jeremy,Ross,29,F))
((Jenny,Dicken,27,F),(Vijay,Sampath,40,M))
((Angs,Dicken,28,M),(Venu,Rao,28,M))
((Mahima,Mohanty,29,F),(Kenny,Oath,28,M))

更新：
如何将分隔符“”更改为其他内容
选项1：使用sed
这是一个非常简单的选项，通过使用sed命令替换 '),(' 图案到 ')#(' 模式，以便分隔符将从 ',' 至 '#' 在同一个输入文件中(note:take backup 执行此sed脚本前输入文件的）

>> sed -i -- 's/),(/)#(/g' inputFile

选项2：在不更改分隔符的情况下对pigscript进行轻微修改
Pig手稿：

--Read each input line as chararray
A = LOAD 'inputFile' AS (line:chararray);

--Remove the character '(',')' from the input
B = FOREACH A GENERATE FLATTEN(REPLACE(line,'[)(]+','')) AS (newline:chararray);

--Split the input using ',' as delimiter, 8 refer to total number of fields
C = FOREACH B GENERATE FLATTEN(STRSPLIT(newline,',',8)) AS (firstname1:chararray,lastname1:chararray,age1:int,sex1:chararray,firstname2:chararray,lastname2:chararray,age2:int,sex2:chararray);

--Group the fields and form tuples 
D = FOREACH C GENERATE TOTUPLE(firstname1,lastname1,age1,sex1) AS details1,TOTUPLE(firstname2,lastname2,age2,sex2) AS details2;

--Now you can do whatever you want.
E = FOREACH D GENERATE details1.firstname1,details2.firstname2;
DUMP E;

请查看清管器文件的复杂方案部分

cat data;
(3,8,9) (mary,19)
(1,4,7) (john,18)
(2,5,8) (joe,18)

A = LOAD data AS (F:tuple(f1:int,f2:int,f3:int),T:tuple(t1:chararray,t2:int));

DESCRIBE A;
A: {F: (f1: int,f2: int,f3: int),T: (t1: chararray,t2: int)}

DUMP A;
((3,8,9),(mary,19))
((1,4,7),(john,18))
((2,5,8),(joe,18))