在针对ApacheHive1.2.1的测试中，这种行为似乎不再以完全相同的方式进行复制。然而，最初的问题很可能与使用相同的字符有关( '\n' )作为 CREATE TABLE 声明。

CREATE TABLE tweet_table(
    tweet STRING
)
ROW FORMAT
    DELIMITED
        FIELDS TERMINATED BY '\n'
        LINES TERMINATED BY '\n'

这不能产生可预测的结果，因为你说过 '\n' 既可以表示字段的结尾，也可以表示整行的结尾。
这就是我对ApacheHive1.2.1进行测试时发生的情况。data.txt的内容是3行数据，每行包含2列，字段之间用制表符隔开( '\t' )线之间用 '\n' .

key1    value1
key2    value2
key3    value3

让我们用字段终止符和行终止符都设置为 '\n' .

hive> CREATE TABLE data_table(
    >     key STRING,
    >     value STRING
    > )
    > ROW FORMAT
    >     DELIMITED
    >         FIELDS TERMINATED BY '\n'
    >         LINES TERMINATED BY '\n';
OK
Time taken: 2.322 seconds
hive> LOAD DATA LOCAL INPATH 'data.txt' INTO TABLE data_table;
Loading data to table default.data_table
Table default.data_table stats: [numFiles=1, totalSize=36]
OK
Time taken: 2.273 seconds
hive> SELECT * FROM data_table;
OK
key1    value1  NULL
key2    value2  NULL
key3    value3  NULL
Time taken: 1.387 seconds, Fetched: 3 row(s)
hive> SELECT key FROM data_table;
OK
key1    value1
key2    value2
key3    value3
Time taken: 1.254 seconds, Fetched: 3 row(s)
hive> SELECT value FROM data_table;
OK
NULL
NULL
NULL
Time taken: 1.384 seconds, Fetched: 3 row(s)

我们可以看到它解释了每一个 "key\tvalue" 作为 key 在表定义中，并假定没有为 value . 这是一个有效的解释，因为表定义声明字段将由 '\n' ，并且没有 '\n' 在输入键和值之后。
现在，让我们在字段终止符设置为的情况下重复相同的测试 '\t' 线路终端设置为 '\n' .

hive> CREATE TABLE data_table(
    >     key STRING,
    >     value STRING
    > )
    > ROW FORMAT
    >     DELIMITED
    >         FIELDS TERMINATED BY '\t'
    >         LINES TERMINATED BY '\n';
OK
Time taken: 2.247 seconds
hive> LOAD DATA LOCAL INPATH 'data.txt' INTO TABLE data_table;
Loading data to table default.data_table
Table default.data_table stats: [numFiles=1, totalSize=36]
OK
Time taken: 2.244 seconds
hive> SELECT * FROM data_table;
OK
key1    value1
key2    value2
key3    value3
Time taken: 1.308 seconds, Fetched: 3 row(s)
hive> SELECT key FROM data_table;
OK
key1
key2
key3
Time taken: 1.376 seconds, Fetched: 3 row(s)
hive> SELECT value FROM data_table;
OK
value1
value2
value3
Time taken: 1.281 seconds, Fetched: 3 row(s)

这一次我们看到了预期的结果。