这是嵌套foreach的好地方：

A = LOAD '$input' AS (ts:int, meta:chararray, key:chararray);
B =
    FOREACH (GROUP A BY key) {
        byts = ORDER A BY ts DESC;
        newest = LIMIT byts 1;
        GENERATE FLATTEN(newest);
    };

测试数据（我将其转换为制表符分隔）：

(20,bar,id1)
(15,hombre,id2)

使用此方法，即使有两行具有最新时间戳，也可以保证每个键只有一行（尽管这对数据可能无关紧要）。

一种方法是：

A = LOAD 'myinput' USING PigStorage(' ') 
    AS (ts:int, meta:chararray, key:chararray) ;

-- Group by key, then find the newest ts for each key
B = FOREACH (GROUP A BY key)
    GENERATE MAX(A.ts) AS newest,
             FLATTEN(A) ;

-- Now that each line has the newest (appropriate) ts, 
-- we can use it to filter the input
C = FILTER B BY newest == ts ;

输出：

(20,20,bar,id1)
(15,15,hombre,id2)

注意如果你不想复制 ts ，现在可以将其投影为：

C = FOREACH (FILTER B BY newest == ts)
    GENERATE A::ts AS ts, A::meta AS meta, A::key AS key ;

但最好还是留下多余的钱 ts 现在独自一人，把它作为以后的计划的一部分 FOREACH 限制工作的数量。
update：此方法将返回所有具有最大 ts 每把钥匙。例如，如果数据如下：

(11,nope,id1)
(20,foo,id1)
(20,bar,id1)

然后它将返回两者 foo 以及 bar .