您可能自己也注意到了（这可能也是您想要的）：构建的jar文件包含您使用时所有依赖jar的全部内容 provided （或 compile )而不是 implementation 在 dependencies 阻止。
问题是你的 jar 任务配置实际上包含了依赖jar的所有内容，包括它们的 META-INF/ 目录文件。这些依赖jar中的一些似乎是经过签名的，因此在其内部包含数字签名 META-INF/ 目录–由您的 jar 任务也是。运行时 java -jar … ，这些签名会妨碍并导致类未找到错误（即使类在jar中）。
一个简单的解决方法是在创建jar文件时排除签名：

jar {
    exclude 'META-INF/*.DSA'
}

学分归这个所以回答。

下面是一个结合了chriki的解决方案和shadowjar方法的答案，shadowjar方法也对我有效。你挑吧！如果这篇文章对你有帮助，请投票给克里基。

plugins {
    // Apply the java plugin to add support for Java
    id 'java'
    // Apply the application plugin to add support for building a CLI application.
    id 'application'
    // This was what I used in my solution
    id 'com.github.johnrengelman.shadow' version '5.2.0'
}
repositories {
    // Use jcenter for resolving dependencies.
    // You can declare any Maven/Ivy/file repository here.
    jcenter()
}
configurations {
        provided
        compile.extendsFrom(provided)
}
dependencies {
    implementation 'com.google.guava:guava:29.0-jre'
    testImplementation 'junit:junit:4.13'
    provided "org.apache.spark:spark-sql_2.11:2.4.4"
    provided "org.apache.spark:spark-hive_2.11:2.4.4"
}
application {
    // Define the main class for the application.
    mainClassName = 'foo.App'
}
test {
    // Use junit platform for unit tests
    useJUnitPlatform()
}
jar {
    // Line below does the trick if you are using 'gradlew jar' 
    // Shout out / big ups to: Chriki
    // Note: My solution (using shadow gradle plugin) 
    // does not require this, but it doesn't hurt
    exclude 'META-INF/*.DSA'            
    manifest {
        attributes "Main-Class": "foo.App"
    }
    zip64 = true
    from {
        configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
    }
}
// This was the second part of what I used in my solution 
// When building, specify: 'gradlew shadowJar' - the jar you want has -all* in it.
// Run with: java -jar  build/libs/foo-all.jar
shadowJar {
    zip64 = true        // I had to specify this twice.. OK.. not gonna lose sleep.
}