这个 having sql中的子句将允许您通过摘要函数筛选查询。下面的查询表示只包含 ColC 分组依据后为0 ColA 以及 ColB .

proc sql noprint;
    create table want as 
        select *
        from have
        group by ColA, ColB
        having sum(ColC) = 0
    ;
quit;

你可以用 not exists 使用相关子查询：

select d.*
from data d
where not exists (select 1
                  from data d2 
                  where d2.cola = d.cola and d2.colb = d.colb and d2.colc = 1
                 );

这将保留所有 cola / colb 没有一个 1 在 colc .
这也可以适用于 delete ，但您似乎需要筛选的结果集。

这里是一个使用双道循环的数据步方法

data have;
input ColA ColB $ ColC;
infile datalines dlm='|';
datalines;
  1  |  a   |  0  
  1  |  a   |  1  
  1  |  b   |  0  
  1  |  b   |  0  
  2  |  a   |  0  
  2  |  a   |  0  
  2  |  b   |  0  
  2  |  b   |  0  
  3  |  a   |  0  
  3  |  a   |  0  
  3  |  b   |  1  
  3  |  b   |  0  
;
data want (drop=c);
    c = 1;
    do _n_ = 1 by 1 until (last.ColB);
        set have;
        by ColA ColB;
        if ColC = 1 then c = 0;
    end;
    do _n_ = 1 to _n_;
        set have;
        if c then output;
    end;
run;

使用通用代码的简单方法：

proc sort data=have;
   by cola colb;
data want;
   merge have (in=in1 where=(colc=1))
         have (in=in2)
         ;
   by cola colb;       
   if ^in1;
run;

第一个have选择colc=1的所有记录，由于我们正在按cola和colb合并，if语句将删除具有相同cola和colb的所有记录，这就是目标。

此外，哈希对象方法

data want;
    if _n_ = 1 then do;
        declare hash h (dataset : 'have(where=(ColC=1))');
        h.definekey ('ColA', 'ColB');
        h.definedone();
    end;
    set have;
    if h.check();
run;