..。或者避免递归：

public static function isVisible(obj:DisplayObject):Boolean
{
    while (obj && obj.visible && obj !== Application.application)
    {
        obj = obj.parent;
    }
    return obj && obj.visible;
}

您想要检查组件属性Visible是否为真，并且这是针对DisplayList中组件的所有父项的，我说的对吗？

public static function isVisible(c : UIComponent) : Boolean {
    if (c == null) return false;
    if (c is Application) return c.visible;
    return c.visible && isVisible(c.parent);
}

对于Visible=False的对象的子级，UIComponent.Visible不一定有效。从文档中：

“在这两种情况下，对象的子级都不会发出SHOW或HIDE事件，除非该对象专门编写了这样做的实现。”

我编写了一个样例应用程序，证实了这一点。您可以做的是遍历显示列表，检查父级上的Visible是否为False。基本上“可见”给出了假阳性，但不应该给出假阴性。以下是我整理的一个快速实用程序：

package
{
    import flash.display.DisplayObject;

    import mx.core.Application;

    public class VisibilityUtils
    {
        public static function isDisplayObjectVisible(obj : DisplayObject) : Boolean {
            if (!obj.visible) return false;
            return checkDisplayObjectVisible(obj);
        }

        private static function checkDisplayObjectVisible(obj : DisplayObject) : Boolean {
            if (!obj.parent.visible) return false;
            if (obj.parent != null && !(obj.parent is Application))
                return checkDisplayObjectVisible(obj.parent);
            else
                return true;
        }
    }
}

我没有在这方面做过任何微不足道的测试，但它应该会让您开始使用。

虽然这看起来很奇怪，但既然您提到了它，我不相信有一个简单的测试来确定一个组件是否真的像Component.isShowing()所暗示的那样在屏幕上可见。

此外，在默认情况下，显示和隐藏事件不会冒泡，因此，如果您希望在ViewStack容器的子代中得到可见性更改的通知，则需要显式侦听它们。实现细节将根据您追求的是哪种行为而有所不同，但举一个简单的例子：

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    <mx:VBox>
        <mx:HBox>
            <mx:Button id="btn1" click="vs.selectedIndex = 0" label="Show 1" />
            <mx:Button id="btn2" click="vs.selectedIndex = 1" label="Show 2" />
        </mx:HBox>
        <mx:ViewStack id="vs" selectedIndex="0">
            <mx:Panel id="panel1">
                <mx:Label id="label1" text="Label 1" show="trace('showing label 1')" hide="trace('hiding label 1')" visible="{panel1.visible}" />
            </mx:Panel>
            <mx:Panel id="panel2">
                <mx:Label id="label2" text="Label 2" show="trace('showing label 2')" hide="trace('hiding label 2')" visible="{panel2.visible}" />
            </mx:Panel>
        </mx:ViewStack>
    </mx:VBox>
</mx:Application>

..。一旦标签的可见属性被绑定到其父面板，您将看到每个标签Fire的显示和隐藏事件。希望这说明了这一点；您可以以最适合您的应用程序的方式对其进行扩展。祝好运!

我正试图以一种可重复使用的方式获得相同的信息。我几乎找到了一种使用getObjectsUnderPoint()的方法--它返回z有序的粒子点下的对象(即使它们不是兄弟，例如ViewStack、Popup、ECC)。

基本上，我在舞台的特定点下打开最上面的显示对象，然后在显示对象层次结构中向上移动以找到测试的对象。如果我找到它，该对象就是可见的(层次结构中不可见的对象应该已经被getObjectsUnderPoint调用过滤掉了)。

这里的问题是，你必须使用对象的非透明点(在我的例子中，我使用了5个像素的偏移量，因为边界变圆了)，否则它将不会被这个函数拾取。

有什么改进的办法吗？

科斯玛

public static function isVisible(object:DisplayObject):Boolean  {
    var point:Point = object.localToGlobal(new Point(5, 5));
    var objects:Array = object.stage.getObjectsUnderPoint(point);
    if (objects.length > 0) {
        if (isDescendantOf(object, objects[objects.length - 1] as DisplayObject)) {
            return true;
        }
    }
    return false;
}

public static function isDescendantOf(parent:DisplayObject, child:DisplayObject):Boolean  {
    while (child.parent != null) {
        if (child.parent === parent) {
            return true;
        } else {
            child = child.parent;
        }
    }
    return false;
}

这就是你真正需要的。“Application.app”检查是徒劳的。

/**
         * Returns `true` if this component is actually shown on screen currently. This could be false even with
         * "visible" set to `true`, because one or more parents could have "visible" set to `false`.
         */
        public static function isShowing (c : DisplayObject) : Boolean {
            while (c && c.visible && c.parent) {
                c = c.parent;
            }
            return c.visible;
        }