如何使用awk显示包含特定单词的文件列

jjjwad0x 于 2022-10-23 发布在 Linux

关注(0)|答案(2)|浏览(227)

我想打印所有包含Word的栏，例如“西瓜”。A正在考虑一起使用这两个公式，因为它们各自独立工作(一个为文件中的每一列做一些操作，另一个检查列是否包含特定的单词)。

awk '{for(i=1;i<=NF-1;i++) printf $i" "; print $i}' a.csv
awk -F"," '{if ($2 == " watermelon") print $2}' a.csv

但当我尝试将它们放在一起时，我的代码不起作用


# !/bin/bash

awk '{for(i=1;i<=NF-1;i++) 
         awk -F"," '{if ($i == " watermelon") 
              print $i}' a.csv    
        }' a.csv

例如，这是我的文件a.csv

lp, type, name, number, letter
1, fruit, watermelon, 6, a
2, fruit, apple, 7, b
3, vegetable, onion, 8, c
4, vegetable, broccoli, 6, b
5, fruit, orange, 5, c

这就是我在搜索西瓜单词时想要得到的结果

name
watermelon
apple
onion
broccoli
orange

linux

来源：https://stackoverflow.com/questions/70230292/how-to-display-file-columns-containing-a-specific-word-using-awk

2条答案

按热度按时间

eblbsuwk1#

$ cat tst.awk
BEGIN { FS=OFS=", " }
NR==FNR {
    for (inFldNr=1; inFldNr<=NF; inFldNr++) {
        if ( $inFldNr == tgt ) {
            hits[inFldNr]
        }
    }
    next
}
FNR==1 {
    for (inFldNr=1; inFldNr<=NF; inFldNr++) {
        if ( inFldNr in hits ) {
            out2in[++numOutFlds] = inFldNr
        }
    }
}
{
    for (outFldNr=1; outFldNr<=numOutFlds; outFldNr++) {
        inFldNr = out2in[outFldNr]
        printf "%s%s", $inFldNr, (outFldNr<numOutFlds ? OFS : ORS)
    }
}

$ awk -v tgt='watermelon' -f tst.awk file file
name
watermelon
apple
onion
broccoli
orange

上面的方法和@JamesBrown的方法之间的主要区别是，在文件的第二遍中，我的脚本只循环要输出的字段，而James的循环遍历所有输入字段，因此在通常情况下，并不是所有的输入字段都必须输出，所以速度会更慢。
关于代码中的printf $i-永远不要这样做，总是对任何输入数据执行printf "%s", $i，因为当您的输入包含像%s这样的printf格式字符时，printf "%s", $i将失败。

赞(0）回复(0）举报 2022-10-23

j2qf4p5b2#

以下是对数据进行两次处理的方法：

$ awk -F', ' '                          # remember to se OFS if you need one
NR==FNR {                               # on the first run
    for(i=1;i<=NF;i++)                  # find 
        if($i=="watermelon")            # watermelon fields
            a[i]                        # and mark them
    next
}
FNR==1 {                                # in case there were no such field
    for(i in a)                         # test 
        next                            # and continue
    exit                                # or exit
}
{                                       # on the second run
    for(i=1;i<=NF;i++)                 
        if(i in a)b=b (b==""?"":OFS) $i # buffer those fields for output
    print b                             # and output
    b=""                                # clean that buffer for next record
}' file file

产出：

name
watermelon
apple
onion
broccoli
orange

赞(0）回复(0）举报 2022-10-23

我来回答

如何使用awk显示包含特定单词的文件列

2条答案

相关问题

热门标签

最新问答