杰森彭尼，
100是默认值，如果要更改缩放比例，则必须增大或减小此值，从10到1000。
我写了一个测试，代码如下：

type
  TFormWebBrowserZoom = class(TForm)
    WebBrowser1: TWebBrowser;
    procedure FormMouseWheelDown(Sender: TObject; Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
    procedure FormMouseWheelUp(Sender: TObject; Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
    procedure FormShow(Sender: TObject);
  private
    FZoom: Integer;
    FLastZoom: Integer; 

    procedure ApplyZoom(ZoomValue: Integer);
    procedure DecZoom;
    procedure IncZoom;
  end;

implementation

const
  OLECMDID_OPTICAL_ZOOM = $0000003F;
  MinZoom = 10;
  MaxZoom = 1000;
  ZoomFactor = 20;
  DefaultZoom = 100;

procedure TFormWebBrowserZoom.FormShow(Sender: TObject);
begin
  WebBrowser1.Navigate('http://www.cesarromero.com.br');
  FZoom := DefaultZoom;
  FLastZoom := DefaultZoom;
end;

procedure TFormWebBrowserZoom.ApplyZoom(ZoomValue: Integer);
var
  pvaIn, pvaOut: OleVariant;
begin
  if ZoomValue = FLastZoom then
    Exit;
  FLastZoom := ZoomValue;
  pvaIn := ZoomValue;
  pvaOut := Null;
  WebBrowser1.ControlInterface.ExecWB(OLECMDID_OPTICAL_ZOOM, OLECMDEXECOPT_DONTPROMPTUSER, pvaIn, pvaOut);
end;

procedure TFormWebBrowserZoom.DecZoom;
begin
  System.Dec(FZoom, ZoomFactor);
  if FZoom < MinZoom then
    FZoom := MinZoom;
  ApplyZoom(FZoom);
end;

procedure TFormWebBrowserZoom.IncZoom;
begin
  System.Inc(FZoom, ZoomFactor);
  if FZoom > MaxZoom then
    FZoom := MaxZoom;
  ApplyZoom(FZoom);
end;

procedure TFormWebBrowserZoom.FormMouseWheelDown(Sender: TObject; Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
begin
  DecZoom;
end;

procedure TFormWebBrowserZoom.FormMouseWheelUp(Sender: TObject; Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
begin
  IncZoom;
end;

从http：//msdn.microsoft.com/en-us/library/cc849094（v=vs.85）.aspx#选择高DPI：

让Web更大：DPI缩放和Internet Explorer 8

选择加入Web浏览器控件（WebOC）的高DPI行为

为了保持与以前开发的WebOC的兼容性，默认情况下，Internet Explorer 8不使用Internet Explorer 8高DPI行为呈现WebOC的Web内容，而是使用Internet Explorer 7行为，该行为放大以绝对值指定的字体（如磅）。要在程序中利用Internet Explorer 8高DPI行为，您需要使用一个名为DOCHOSTUIFLAG_DPI_AWARE的DOCHOSTUIFLAG。您可以通过使用GetHostInfo方法来使用此标志，该方法将DOCHOSTUIINFO结构作为其参数之一。而DOCHOSTUIINFO将一个名为dwFlags的operator DWORD作为其成员之一，可以由一个或多个DOCHOSTUIFLAG值组成。必须在dwFlags中包含DOCHOSTUIFLAG_DPI_AWARE，以便在WebOC中利用Internet Explorer 8高DPI行为。
选择高DPI行为后，模拟WebOCs的HTML内容如何显示的快捷方法是打开等效的HTML内容（在HTML文件中合成），只需在等效的缩放设置下检查渲染（120 DPI到125%缩放，144 DPI到150%缩放）。我们建议您在实际的高DPI场景中测试WebOC，以完全确保HTML内容按您希望的方式呈现。