我将跳过有关regexp如何是解析HTML的坏方法的部分，因为有时快速而肮脏的解决方案已经足够好了。
你不能在这样的字符串中使用运算符。++只被当作纯文本（正如你所发现的）。你必须使用/e标志来指示替换应该作为Perl代码来计算，然后使用适当的表达式，比如：

$content =~ s/SIZE="(\d+)">/'SIZE="' . ($1 + 1) . '">'/eg;

不能使用$1++有两个原因。第一，它会在返回值后执行增量，因此您会用8而不是9替换8。第二，$1是只读值，增量会修改它。

您应该考虑使用HTML解析器，如HTML::TokeParser::Simple：

#!/usr/bin/perl

use strict; use warnings;

use HTML::TokeParser::Simple;

my $content = "<TD><FONT STYLE=\"font-family:Verdana, Geneva, sans-serif\" SIZE=\"8\">this is just a bunch of text</FONT></TD>";
$content .= "<TD><FONT STYLE=\"font-family:Verdana, Geneva, sans-serif\" SIZE=\"3\">more text</FONT></TD>";

my $parser = HTML::TokeParser::Simple->new( \$content );

while ( my $token = $parser->get_token ) {
    if ( $token->is_start_tag('font') ) {
        my $font_size = $token->get_attr('size');
        if ( defined $font_size ) {
            ++ $font_size;
            $token->set_attr(size => $font_size);
        }
    }
    print $token->rewrite_tag->as_is;
}

输出量：

<td><font style="font-family:Verdana, Geneva, sans-serif" size="9">this is just
a bunch of text</font></td><td><font style="font-family:Verdana, Geneva, 
sans-serif" size="4">more text</font></td>

使用e修饰符/标志在正则表达式中执行脚本，例如

$content=~s/SIZE="(\d+)">/'SIZE="'.($1+1).'">'/ge;

#!/usr/bin/perl -w    

use strict;    

   sub main{    
      my $c = qq{<TD><FONT STYLE="font-family:Verdana, Geneva, sans-serif" SIZE="8">this is just a bunch of text</FONT></TD>\n}
            . '<TD><FONT STYLE="font-family:Verdana, Geneva, sans-serif" SIZE="3">more text</FONT></TD>';

      $c =~ s/(SIZE=\")(\d+)(\")/$_=$2+1;"$1$_$3"/eg;

      print "$c\n";      
         #<TD><FONT STYLE="font-family:Verdana, Geneva, sans-serif" SIZE="9">this is just a bunch of text</FONT></TD>
         #<TD><FONT STYLE="font-family:Verdana, Geneva, sans-serif" SIZE="4">more text</FONT></TD>  
   }    

   main();