plugins区块取代了apply plugin区块。
它使用以下语法：

plugins {
    id «plugin id» version «plugin version» [apply «false»]
}

在插件声明之后的apply false意味着它只是被添加到类路径中，而不是应用到项目中。如果你想在根项目中声明所有插件及其版本，这很有用。
在您的情况下：

plugins {
    id 'com.android.application' version '7.3.1' apply false
}

取代：

buildscript {
  repositories {
    //...
  }
  dependencies {
    classpath 'com.android.tools.build:gradle:x.x.x'
  }
}

apply plugin: 'com.android.application'

在settings.gradle中，您可以找到用于查找插件的存储库：

pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
    }
}

您可以在相同的块中添加其他的库和其他的插件。
然后在您的app/build.gradle文件中，您可以找到：

plugins {
    id 'com.android.application'
}

在同一个文件中，您可以添加dependencies块来添加其他依赖项：

dependencies {

    implementation 'androidx.core:core-ktx:1.7.0'
    //
}

并且repositories块

repositories {
        google()
    }

在settings.gradle中，您还可以找到模块依赖项所使用的存储库：

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
    }
}