要测试 ActiveCell 是否在 Table1 的正文中，请执行以下操作：

Sub qwerty()

   If Intersect(ActiveCell, ActiveSheet.ListObjects("Table1").DataBodyRange) Is Nothing Then
      MsgBox "activecell not in Table1"
   Else
      MsgBox "activecell in Table1"
   End If

End Sub

更通用的解决方案，适用于其他表

Sub Demo()
    Dim r As Range
    Dim lo As ListObject

    Set r = ActiveCell
    Set lo = r.ListObject
    If Not lo Is Nothing Then
        Select Case lo.Name
            Case "Table1"
                If r.Row = lo.Range.Row Then
                    MsgBox "In Table1 Header"
                Else
                    MsgBox "In Table1 Body"
                End If
            Case "SomeOtherTable"
                '...
        End Select
    Else
        MsgBox "Not in any table"
    End If
End Sub

通常，我们对在表的DataBodyRange中执行的工作感兴趣，Excel为我们提供了表的该区域的快捷方式。对于名为“myTable”的表，您可以使用[myTable]在代码中直接访问DataBodyRange。
因此，对于ActiveCell的包含表位置测试，可以如下进行测试：

If Not Intersect(ActiveCell, [myTable]) Is Nothing Then

Range对象有一个ListObject属性，该属性将返回Range的表格。您所要做的就是测试该单元格是否在任何表格中：

If ActiveCell.ListObject Is Nothing Then
    ...

并查看它是否在您特定表中：

If ActiveCell.ListObject.Name = "MyTable" Then
    ...

就大功告成了！
比使用Application.Intersect(...)干净得多。chris neilsen's的回答也暗示了这一点。

我使用下面的代码行：

ActiveCell.ListObject.Name

或sub：

Sub IsActiveCellInTable()
    'If active cell in table then get name'
    Dim strTblName As String

        'Disable error checking'
        On Error Resume Next 

        strTblName = ActiveCell.ListObject.Name

        'Reset error checking'
        On Error GoTo 0 

        If strTblName <> "" Then
            MsgBox "Cell (" & ActiveCell.Address & ") is included in: " & strTblName
        Else
            MsgBox "Cell (" & ActiveCell.Address & ") is not included in table."
        End If

    End Sub