我会尝试这种方式

flatten(X) -> lists:reverse(flatten(X,[])).

flatten([],Acc) -> Acc;
flatten([H|T],Acc) when is_list(H) -> flatten(T, flatten(H,Acc));
flatten([H|T],Acc) -> flatten(T,[H|Acc]).

测试

my:flatten([[1,[2,[3],[]]], [[[4]]], [5,6]]).
[1,2,3,4,5,6]

**UPD：**或者这种方式，没有保护和反向，只有递归调用和模式匹配。

flatten(X)               -> flatten(X,[]).

flatten([],Acc)          -> Acc;
flatten([[]|T],Acc)      -> flatten(T, Acc);
flatten([[_|_]=H|T],Acc) -> flatten(T, flatten(H,Acc));
flatten([H|T],Acc)       -> flatten(T,Acc++[H]) .

一些不同的解决方案，变得越来越聪明：

%% Lift nested lists to the front of the list.
flatten1([[H|T1]|T2]) -> flatten1([H,T1|T2]);
flatten1([[]|T]) -> flatten1(T);
flatten1([E|T]) -> [E|flatten1(T)];
flatten1([]) -> [].

或

%% Keep a list of things todo and put tails onto it.
flatten2(L) -> flatten2(L, []).

flatten2([H|T], Todo) ->
    flatten2(H, [T|Todo]);
flatten2([], [H|Todo]) -> flatten2(H, Todo);
flatten2([], []) -> [];
flatten2(E, Todo) -> [E|flatten2(Todo, [])].

或

%% Work from the back and keep a tail of things done.
flatten3(L) -> flatten3(L, []).

flatten3([H|T], Tail) ->
    flatten3(H, flatten3(T, Tail));
flatten3([], Tail) -> Tail;
flatten3(E, Tail) -> [E|Tail].

这些都是只有模式匹配和递归，但他们可以通过一些保护类型测试来改进。使用++是低效的，因为它每次都复制列表。lists模块使用了带有保护类型测试的最后一个版本，而不是最后一个子句。

漂亮简洁直白的版本：

append([H | T], L) -> [H | append(T, L)];
append([], L) -> L.

flatten([[_|_]=H|T]) -> append(flatten(H), flatten(T));
flatten([[]|T]) -> flatten(T);
flatten([H|T]) -> [H|flatten(T)];
flatten([]) -> [].

书中定义的concatenate/1作为一个扁平化函数工作，它只扁平化一层。（[[1],[2]]变成[1,2]，[[[1]],[[2]]]变成[[1],[2]]，等等。）提示中建议的策略是完全扁平化，不是通过在flat/1中定义新逻辑，而是通过在flat/1的递归调用中使用concatenate/1。

concatenate(Ls) ->
    reverse(concatenate(Ls, [])).

concatenate([], Acc) ->
    Acc;
concatenate([[]|Rest], Acc) ->
    concatenate(Rest, Acc);
concatenate([[H|T]|Rest], Acc) ->
    concatenate([T|Rest], [H|Acc]);
concatenate([H|T], Acc) ->
    concatenate(T, [H|Acc]).

flatten(L) ->
    flatten(L, []).

flatten([], Acc) ->
    Acc;
flatten(L, Acc) ->
    Concatted = concatenate(L),
    [Non_lists|Remainder] = find_sublist(Concatted),
    flatten(Remainder, concatenate([Acc, Non_lists])).

find_sublist(L) ->
    find_sublist(L, []).

find_sublist([], Acc) ->
    reverse(Acc);
find_sublist(L = [[_|_]|_], Acc) ->
    [reverse(Acc)|L];
find_sublist([H|T], Acc) ->
    find_sublist(T, [H|Acc]).

tests() ->
    [1,2,3,4,4,5,6,7,8] = flatten([[1,[2,[3],[]]], [[[4,[4]]]], [[5],6], [[[]]], [], [[]], [[[7, 8]]]]),
    [1,2] = flatten([[1,2]]),
    [1,2,3] = flatten([[1],[2],[3]]),
    [1,2,3,4,5,6] = flatten([[1,[2,[3],[]]], [[[4]]], [5,6]]),
    tests_successful.

问题的关键是“分而治之”。
另一个额外的功能“列表：反向”和一个运算符“++”用于节省编程时间。

my_flat([],Result)->
    lists:reverse(Result);
my_flat([H|T],Result) when is_atom(H) ->
    case T of
    []-> 
        my_flat([],[H|Result]);
    _Else ->
        my_flat(T,[H|Result])
    end;
my_flat([H|T],Result) when is_number(H)->
    case T of
    []->
        my_flat([],[H|Result]);
    _Else ->
        my_flat(T,[H|Result])
    end;
my_flat([H|T],Result) ->
my_flat(H,Result)++my_flat(T,[]).

对于您的测试：测试：my_flat（[[1，[2，[3]，[]]]，[4]，[5，6]]，[]）.

这里还有另一种选择，不使用累加器而用Erlang列表进行append操作（++）：

flatten([[_|_]=R | Tail]) -> flatten(R)++flatten(Tail);
flatten([V|Tail]) -> flatten(V)++flatten(Tail);
flatten([])->[];
flatten(V)->[V].