正如罗恩在评论中所写的，Mac上没有Scripting.Dictionary--字典是 * 微软脚本库 *（scrrun.dll）的一部分，而dll（动态链接库）在Mac上不存在。
现在，使用Dictionary进行重复检查通常是一个好主意，因为它非常快速且易于使用，然而，当涉及到简单检查字符串是否包含字符时，它有点矫枉过正。
下面的函数将把源字符串中的每个字符复制到目标字符串中（如果目标字符串中还没有）-使用InStr完成检查。
我已经将参数类型更改为Variant，并使用函数CStr将内容转换为字符串-使用该函数，您可以对几乎所有数据类型（范围、字符串，甚至数字或日期）调用该函数。

Function RemoveDuplicateChars(param As Variant) As String
    Dim sourceString As String, i As Long
    sourceString = CStr(param)
    For i = 1 To Len(sourceString)
        Dim xChar As String
        xChar = Mid(sourceString, i, 1)
        If InStr(RemoveDuplicateChars, xChar) = 0 Then
            RemoveDuplicateChars = RemoveDuplicateChars & xChar
        End If
    Next
End Function

更新：为了完整起见，我添加了一个可选的第二个参数，这样函数就可以不区分大小写（如果字符串包含一个大写和一个小写字符，则只复制其中一个）

Function RemoveDuplicateChars(param As Variant, Optional IgnoreCase As Boolean = False) As String
    Dim sourceString As String, i As Long
    sourceString = CStr(param)
    For i = 1 To Len(sourceString)
        Dim xChar As String
        xChar = Mid(sourceString, i, 1)
        Dim compareMethod As Long
        compareMethod = IIf(IgnoreCase, vbTextCompare, vbBinaryCompare)
        If InStr(1, RemoveDuplicateChars, xChar, compareMethod) = 0 Then
            RemoveDuplicateChars = RemoveDuplicateChars & xChar
        End If
    Next
End Function