不确定这是否能和用户定义的函数一起工作......可能在高级选项中禁用“更新到其他文档的链接”。很确定它不会工作。
关于你的第二个问题，我可以想到两种方法。
或者遍历每个工作表，复制 * 所有 * 单元格并将值粘贴回去：

Sub PlaceValues()

    Dim wrkBk As Workbook
    Set wrkBk = ThisWorkbook 'This is the file containing the code.
                             'You could change it to look at some other open workbook.
    
    Dim wrksht As Worksheet
    For Each wrksht In wrkBk.Worksheets
        With wrksht
            .Cells.Copy
            .Cells.PasteSpecial Paste:=xlPasteValues
        End With
    Next wrksht
    
End Sub

一个更有针对性的办法是取代具体的公式。
这里的一个缺点是替换SUM公式也会替换SUMIF，因为它包含文本SUM。

Public Sub Test()

    ReplaceFormula "FIN_G_EN"
    ReplaceFormula "SUM"

End Sub

Public Sub ReplaceFormula(FormulaText As String)

    Dim wrkBk As Workbook
    Set wrkBk = ThisWorkbook
    
    Dim wrksht As Worksheet
    For Each wrksht In wrkBk.Worksheets
        Dim rFound As Range
        With wrksht.Cells
            Set rFound = .Find(What:=FormulaText, _
                               LookIn:=xlFormulas, _
                               LookAt:=xlPart, _
                               MatchCase:=True)
            If Not rFound Is Nothing Then
                Do
                    rFound.Value = rFound.Value
                    Set rFound = .FindNext(rFound)
                Loop While Not rFound Is Nothing
            End If
        End With
    
    Next wrksht

End Sub