Sub ImportTextFileDatatoExcel()

    Const LOGS = "E:\Logs"
    Const DBUG = False ' True for debug messages
    
    Dim wb As Workbook, ws As Worksheet
    Dim fso As Object, ts As Object, folder As Object, f As Object
    Dim dtFirst As Date, dtLast As Date, dt As Date
    Dim arFile, arLine, v, yy As String, mmm As String, dd As String
    Dim n As Long, i As Long, r As Long, c As Long, s As String
    
    s = InputBox("Enter Start Date dd/mm/yyyy", "Start Date", Format(Date, "dd/mm/yyyy"))
    If IsDate(s) Then
        dtFirst = CDate(s)
    Else
        MsgBox s & " is not a valid date", vbCritical
        Exit Sub
    End If
     
    s = InputBox("Enter End Date dd/mm/yyyy", "End Date", Format(dtFirst, "dd/mm/yyyy"))
    If IsDate(s) Then
        dtLast = CDate(s)
    Else
        MsgBox s & " is not a valid date", vbCritical
        Exit Sub
    End If
    
    s = "From " & Format(dtFirst, "dd mmm yyyy") & " to " & Format(dtLast, "dd mmm yyyy")
    If vbNo = MsgBox(s, vbYesNo, "Confirm Yes/No") Then
         Exit Sub
    End If
    
    ' start scanning logs
    Set wb = ThisWorkbook
    Set ws = wb.ActiveSheet
    ws.Cells.ClearContents
    r = 2
    
    ' select files
    Dim arLogs
    With Application.FileDialog(msoFileDialogFilePicker)
        .InitialFileName = LOGS
        .AllowMultiSelect = True
        .Filters.Add "Log files or Text", "*.log; *.txt, 1"
        .Show
        n = .SelectedItems.Count
        If n = 0 Then Exit Sub
        ReDim arLogs(1 To n)
        For i = 1 To n
            arLogs(i) = .SelectedItems(i)
        Next
    End With
    
    ' scan files
    Set fso = CreateObject("Scripting.FileSystemObject")
    For n = 1 To UBound(arLogs)
        Set f = fso.getFile(arLogs(n))
                
        ' read in file
        If DBUG Then Debug.Print f.Name
        Set ts = f.OpenAsTextStream(1, -2) ' read, default encoding
        s = ts.readall
        ts.Close
        
        ' scan each line
        arFile = Split(s, vbCrLf)
        For Each v In arFile
        
            ' convert 10Jan23 to 10-Jan-23
            s = Mid(CStr(v), 10, 7)
            dd = Left(s, 2)
            mmm = Mid(s, 3, 3)
            yy = Right(s, 2)
            s = dd & "-" & mmm & "-" & yy
           
            ' check valid date
            If IsDate(s) Then
                dt = CDate(s)
                If (dt >= dtFirst) And (dt <= dtLast) Then
                
                    ' split line into columns
                    arLine = Split(CStr(v), ";")
                    c = 1 + UBound(arLine)
                    ws.Cells(r, 1).Resize(, c) = arLine
                    r = r + 1
                    
                    If DBUG Then Debug.Print s, Format(dt, "yyyy-mm-dd"), v
                Else
                    If DBUG Then Debug.Print "outside range", s, v
                End If
                
            Else
                If DBUG Then Debug.Print "not a date", s, v
            End If
           
        Next
    Next
    ' result
    MsgBox n - 1 & " logs scanned. " & vbLf & _
           r - 2 & " lines extracted", vbInformation
    
End Sub