你可以使用一个自定义类来创建一个框架中所有按钮的"控件数组"。参见（例如）https://bettersolutions.com/excel/macros/vba-control-arrays.htm
大概是这样的
在工作表代码模块中-如果在C3：C13中选择了单元格，则显示窗体

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim frm As frmSelect, c As Range
    
    If Target.Cells.CountLarge > 1 Then Exit Sub
    Set c = Application.Intersect(Me.Range("C3:C13"), Target)
    If c Is Nothing Then Exit Sub
    
    Set frm = New frmSelect  'create userform
    Set frm.theCell = c      'assign the selected cell
    frm.Show                 'show the form
    Unload frm
End Sub

用户表单frmSelect

Option Explicit

Dim rng As Range
Dim col As Collection 'must be Global (to the form)

Private Sub UserForm_Activate()
    Dim con As Object, evt As Object
    
    Set col = New Collection
    For Each con In Me.Frame1.Controls 'buttons are in Frame1
        Set evt = New clsButton        'assuming all contained controls are buttons...
        evt.Init con, Me               'set up the class instance
        col.Add evt                    'store the object in the collection
    Next con
End Sub

'the cell to be populated
Property Set theCell(c As Range)
    Set rng = c
End Property

'called from the event class on clicking a button
Public Sub SetCell(txt As String)
    rng.Value = txt
    Me.Hide
End Sub

最后，类clsButton用于管理事件

Option Explicit

Private WithEvents btn As MSForms.CommandButton
Private frm As frmSelect

'set up the class instance
Public Sub Init(objBtn As MSForms.CommandButton, objFrm As Object)
    Set btn = objBtn
    Set frm = objFrm
End Sub

'handle the click event
Private Sub btn_Click()
    frm.SetCell btn.Caption 'call Sub in the form
End Sub