此方法的工作原理如下：

waitUntil {
            def job = Jenkins.instance.getItemByFullName("Project U")
            !job.isBuilding() && !job.isInQueue()
        }

当这个下游作业启动时，它将检查上游作业是处于活动状态还是在排队，如果是，它将等待直到它的构建完成。
我还不能找到如何以编程方式访问当前作业的上游作业，因此需要复制作业名称。（有一个方法getBuildingUpstream（），它会方便得多，但我还没有找到从Job示例获取当前Project对象的方法。）
我最终在Jenkins共享库中创建了这个函数：

/*
    vars/waitForJobs.groovy
    
    Wait until none of the upstream jobs is building or being queued any more

    Parameters:
    
    upstreamProjects   String with a comma separated list of Jenkins jobs to check 
                       (use same format as in upstream trigger) 
    
*/

def call( Map params) {

    projects = params['upstreamProjects'].split(', *')
    
    echo 'Checking the following upstream projects:' 
    if ( projects.size() == 0) {
        echo 'none'
    } else {
        projects.each {project ->
            echo "${project}"
        }
    }
    
    waitUntil {
        def running = false
        projects.each {project ->
            def job = Jenkins.instance.getItemByFullName(project)
            if (job == null) {
                error "Project '${project} not found"
            }
            if (job.isBuilding()) {
                echo "Waiting for ${project} (executing)"
                running = true             
            }
            if (job.isInQueue()) {
                echo "Waiting for ${project} (queued for execution)"
                running = true
            }
        }
        return !running
    }

}

好处是我可以直接从上游触发器复制参数，因为它使用完全相同的格式。下面是一个例子，它看起来像什么：

pipeline {
[...]   
    triggers {
        pollSCM('H/5 * * * *')
        upstream(upstreamProjects: 'Project U1, Project U2, Project U3', threshold: hudson.model.Result.SUCCESS)
    }    
[...]
    stages {
        stage('Wait') {
            steps {
                script{
                    // Wait for upstream jobs to finish
                    waitForJobs(upstreamProjects: 'Project U1, Project U2, Project U3')
                }
            }
[...]
        }
    }
}