我最近遇到了类似的mysql，gradle，flyway和jooq的案例。基于gradle-jooq-plugin（https://github.com/etiennestuder/gradle-jooq-plugin/blob/master/example/）的例子，我为我的案例提出了可行的解决方案，只需稍作修改，它也应该适用于您的案例：

import org.testcontainers.containers.MySQLContainer

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
    }
    dependencies {
        classpath 'org.testcontainers:mysql:1.17.3'
        classpath 'mysql:mysql-connector-java:8.0.29'
        classpath 'org.flywaydb:flyway-mysql:9.0.1'

    }
}

plugins {
    id 'java'
    id 'org.flywaydb.flyway' version '9.0.1'
    id 'nu.studer.jooq' version '7.1.1'
}

repositories {
    mavenLocal()
    mavenCentral()
}

configurations {
    flywayMigration
}

dependencies {
    jooqGenerator('mysql:mysql-connector-java:8.0.29')
}

task mysqlContainer {
    var instance = new MySQLContainer("mysql:8.0.29")
            .withDatabaseName('example')
    instance.start()
    mysqlContainer.ext.jdbcUrl = instance.getJdbcUrl()
    mysqlContainer.ext.username = instance.getUsername()
    mysqlContainer.ext.password = instance.getPassword()
    mysqlContainer.ext.databaseName = instance.getDatabaseName()
    mysqlContainer.ext.instance = instance
}

flyway {
    locations = ['filesystem:./src/main/resources/db/migration']
    configurations = ['flywayMigration']
    url = mysqlContainer.jdbcUrl
    user = mysqlContainer.username
    password = mysqlContainer.password
}

jooq {
    configurations {
        main {
            generationTool {
                logging = org.jooq.meta.jaxb.Logging.WARN
                jdbc {
                    driver = 'com.mysql.cj.jdbc.Driver'
                    url = mysqlContainer.jdbcUrl
                    user =mysqlContainer.username
                    password = mysqlContainer.password
                }
                generator {
                    name = 'org.jooq.codegen.DefaultGenerator'
                    database {
                        name = 'org.jooq.meta.mysql.MySQLDatabase'
                        includes = '.*'
                        inputSchema = mysqlContainer.databaseName
                        outputSchemaToDefault = true
                    }
                    target {
                        packageName = 'com.example.jooq'
                    }
                }
            }
        }
    }
}

tasks.named('generateJooq').configure {
    dependsOn tasks.named('mysqlContainer')
    dependsOn tasks.named('flywayMigrate')

    inputs.files(fileTree('src/main/resources/db/migration'))
            .withPropertyName('migrations')
            .withPathSensitivity(PathSensitivity.RELATIVE)

    allInputsDeclared = true
    doLast {
        mysqlContainer.instance.stop()
    }
}

我们使用下面的流程（它是Kotlin，只包含脚本中与JOOQ资源相关的部分）。与this answer的主要区别是，我的流程在你只运行generateJooq任务时会启动一个新容器。另一个流程在每个任务中都会运行一个新容器。

...

val containerInstance: PostgreSQLContainer<Nothing>? = if ("generateJooq" in project.gradle.startParameter.taskNames) {
    PostgreSQLContainer<Nothing>(
        DockerImageName.parse(
            "postgres:14.4-alpine",
        ),
    ).apply {
        withDatabaseName("my-db")
        start()
    }
} else {
    null
}

flyway {
    url = containerInstance?.jdbcUrl
    user = containerInstance?.username
    password = containerInstance?.password
}

jooq {
    version.set("3.17.5") // default (can be omitted)
    edition.set(nu.studer.gradle.jooq.JooqEdition.OSS) // default (can be omitted)

    configurations {
        create("main") { // name of the jOOQ configuration
            generateSchemaSourceOnCompilation.set(false) // default (can be omitted)
            jooqConfiguration.apply {
                logging = Logging.ERROR
                jdbc.apply {
                    driver = "org.postgresql.Driver"
                    url = containerInstance?.jdbcUrl
                    user = containerInstance?.username
                    password = containerInstance?.password
                }
                generator.apply {
                    name = "org.jooq.codegen.DefaultGenerator"
                    database.apply {
                        name = "org.jooq.meta.postgres.PostgresDatabase"
                        inputSchema = "public"
                        isIncludeIndexes = false
                        excludes = "flyway.*"
                    }
                    target.apply {
                        packageName = "mypackage"
                        directory = "src/main/java"
                    }
                    strategy.name = "org.jooq.codegen.DefaultGeneratorStrategy"
                }
            }
        }
    }
}

// This validation is optional. In our flow, we use flyway migrate plugin in only jooq resources generation flow
tasks.flywayMigrate.configure {
    val taskNames = project.gradle.startParameter.taskNames
    if ("flyMigrate" in taskNames && "generateJooq" !in taskNames) {
        throw IllegalArgumentException("Flyway migrate is only available for generateJooq task")
    }
}

tasks.named("generateJooq").configure {
    dependsOn(tasks.named("flywayMigrate"))
    doLast {
        containerInstance?.stop()
    }
}

...