在Haskell中，可以定义计算函数返回类型的类型族：

type family Result f where
  Result (a -> b) = Result b
  Result b = b

以及其参数类型的类型级列表（按相反顺序）：

type Arguments f = Arguments' '[] f
type family Arguments' args f where
  Arguments' args (a -> b) = Arguments' (a ': args) b
  Arguments' args b = args

这将允许您编写：

myFunc :: forall f arguments output m.
  ( Monad m
  , Result f ~ m output
  , Arguments f ~ arguments
  ) => f -> m f
myFunc fn = pure fn

这将使类型变量output和arguments在函数体中可用：

myFunc :: forall f arguments output m.
  ( MonadIO m
  , Result f ~ m output
  , Arguments f ~ arguments
  , Typeable arguments, Typeable output
  ) => f -> m f
myFunc fn = do
  liftIO . putStrLn $ "Result: " ++ show (typeRep (Proxy @output))
  liftIO . putStrLn $ "Arguments: " ++ show (typeRep (Proxy @arguments))
  pure fn

这可能适合也可能不适合您要做的事情，它可能在PureScript中工作也可能不工作。
不管怎样，这里有一个自包含的Haskell例子：

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TypeApplications #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE UndecidableInstances #-}

import Control.Monad.IO.Class
import Data.Typeable

type family Result f where
  Result (a -> b) = Result b
  Result b = b

type Arguments f = Arguments' '[] f
type family Arguments' args f where
  Arguments' args (a -> b) = Arguments' (a ': args) b
  Arguments' args b = args

myFunc :: forall f arguments output m.
  ( MonadIO m
  , Result f ~ m output
  , Arguments f ~ arguments
  , Typeable arguments, Typeable output
  ) => f -> m f
myFunc fn = do
  liftIO . putStrLn $ "Result: " ++ show (typeRep (Proxy @output))
  liftIO . putStrLn $ "Arguments: " ++ show (typeRep (Proxy @arguments))
  liftIO . putStrLn $ ""
  pure fn

resultType :: forall f r. (Result f ~ r, Typeable r) => f -> String
resultType _ = show $ typeRep (Proxy @r)

main :: IO ()
main = do
  _ <- myFunc (pure . length :: String -> IO Int)
  _ <- myFunc ((\x y -> pure (x+y)) :: Double -> Double -> IO Double)
  putStrLn "done"