如果您不希望这些尾随逗号，那么您需要读取每一行，直到该行的最后一个值，而不是假设所有行都有相同的结束点。
这里有一个你可以使用的方法：

Sub NEWMACRO()

    Dim sLine As String, sep As String
    Dim rng As Range, ws As Worksheet
    Dim lLastRow As Long, arr, mylogfile, rw As Long, col As Long
    
    Set ws = ActiveSheet 'for example
    'last occupied row on the sheet
    lLastRow = ws.Cells.Find(what:="*", After:=ws.Range("A1"), _
                LookAt:=xlPart, LookIn:=xlFormulas, _
                SearchOrder:=xlByRows, SearchDirection:=xlPrevious, _
                        MatchCase:=False).Row
        
    mylogfile = FreeFile()
    Open "C:\Temp\Test2.csv" For Output Access Write As mylogfile
    
    'loop over all rows
    For rw = 1 To lLastRow
        sLine = "": sep = ""
        'read only the occupied part of the row
        arr = asArray(ws.Range(ws.Cells(rw, 1), _
                       ws.Cells(rw, ws.Columns.Count).End(xlToLeft)))
        For col = LBound(arr, 2) To UBound(arr, 2)
            sLine = sLine & sep & arr(1, col)
            sep = ","
        Next col
        Print #mylogfile, sLine
    Next rw
    
    Close mylogfile
End Sub

'read a range into a 2D array, allowing for the single-cell case
Function asArray(rng As Range)
    Dim arr()
    If rng.Cells.CountLarge = 1 Then
        ReDim arr(1 To 1, 1 To 1)
        arr(1, 1) = rng.Value
        asArray = arr
    Else
        asArray = rng.Value
    End If
End Function