把四元数转换成32位整数，你就可以设置了。CPAN上有一些模块可以帮你做这件事，但它归结起来像这样

sub ip2dec ($) {
    unpack N => pack CCCC => split /\./ => shift;
}

if (ip2dec($remoteip) <= ip2dec('xx.xx.xx.204') && ip2dec($remoteip) >= ip2dec('xx.xx.xx.145')) {
   # do something
}

例如，111.222.233.244被转换为1876879860（0x6fdee9f4，01101111110111101110100111110100），因此您不仅可以比较（排序）地址，还可以对其应用位掩码。

您可以使用Socket模块和inet_aton方法，将一个范围转换为一个数组，并通过该数组执行grep。

use v5.16;
use strict;
use warnings;
use Socket qw/inet_aton/;
#using 10.210.14 as the first three octects
#convert range into binary
my @addressrange = map {unpack('N',inet_aton("10.210.14.$_"))} (145..204);
#address to test
my $address = $ARGV[0];
#grep for this binary in the range
unless(grep {unpack('N',inet_aton($address)) eq $_} @addressrange) {
  say "Address not part of the range"
}
else {
  say "Address is part of the range"
}

然后跑

perl iphelp.pl 10.210.14.15
Address not part of the range

perl iphelp.pl 10.210.14.145
Address is part of the range

自己处理逻辑并不是一件大事，但正如前面所指出的，CPAN模块也可以为您完成这一工作。在本例中，为了简化输出，我缩短了范围的长度：

use strict;
use warnings;
use feature qw( say );

use Net::Works::Address;

my $lower = Net::Works::Address->new_from_string( string => '10.0.0.145' );
my $upper = Net::Works::Address->new_from_string( string => '10.0.0.150' );

foreach my $i ( 0 .. 255 ) {
    my $ip   = '10.0.0.' . $i;
    my $auth = check_ip( $ip );
    say "$ip is OK" if $auth;
}

sub check_ip {
    my $ip = shift;
    my $address = Net::Works::Address->new_from_string( string => $ip );
    return ( $address <= $upper && $address >= $lower );
}

输出为：

10.0.0.145 is ok
10.0.0.146 is ok
10.0.0.147 is ok
10.0.0.148 is ok
10.0.0.149 is ok
10.0.0.150 is ok