您忽略的关键信息是decorator在编译时被调用一次。
decorator将需要用一个包围真实&c的子来替换&c，以获得所需的结果。

use Attribute::Handlers;
use Sub::Name qw( subname );

sub Wrap :ATTR(CODE) {
   my ( $pkg, $sym, $old_sub, $attr, $data, $phase, $fn, $ln ) = @_;
   my ( $before, $after ) = @$data;

   my $name = *{ $sym }{ NAME };
 
   my $new_sub = subname "wrapped_$name", sub {
      wantarray
      ? $after->(         $old_sub->( $before->( @_ ) )   )
      : $after->( scalar( $old_sub->( $before->( @_ ) ) ) )
   };

   no warnings qw( redefine );
   *$sym = $new_sub;
}

受试：

sub f :Wrap(
    sub { $_[0], $_[1]+50 },
    sub { $_[0]+7000 },
) {
    $_[1]+600
}

say __PACKAGE__->f( 4 );  # 7654

注意：这使用了OP自己的答案中的调用约定，这与OP问题中的调用约定不同。

以下是怀疑论者的解决方案。方法的输入和输出过滤器分别：

use Attribute::Handlers ;
use JSON ;

my $json = JSON->new( )->utf8( 0 ) ;

sub json_input:ATTR {
    my ( undef( ) , $symbol, $referent , undef( ) , $data ) = @_ ;

    $data ||= [ 0 ] ;

    *$symbol = sub {
        return $referent->( @_ ) unless @_ > 1 ;

        my ( $self , @args ) = @_ ;
        my @idxs = keys ( %{
            { +
                map {
                    do {
                        if ( $_ >= 0 ) {
                            $_
                        } else {
                            @args + $_
                        }
                    } => undef( ) ,
                } grep {
                    ( abs( $_ ) >=0 ) && ( abs( $_ ) < @args )
                } @$data
            }
        } ) ;

        $_ = $json->decode( $_ ) foreach grep { defined( $_ ) } @args[ @idxs ] ;

        $referent->( $self , @args )
    }
}
sub json_output:ATTR {
    my ( undef( ) , $symbol, $referent ) = @_ ;

    *$symbol = sub {
        my @data = $referent->( @_ ) ;

        $json->encode( @data > 1 ? \@data : @data )
    }
}
sub test
    :json_input( 0 , 2 , 10 ) # позиции аргументов, которые нужно раскодировать перед применением
    :json_output
{
    my ( $self , $data0 , $data1 , $data2 ) = @_ ;

    $data0->{ 'a' } ,
    $data2->{ 'x' }
}

print( __PACKAGE__->test( << '.' ,  << '.' ,  << '.' ) ) ; # many string arguments
{
    "a" : { "b" : "d" } ,
    "c" : "d"
}
.
{
    "d" : { "e" : "r" } ,
    "c" : "d"
}
.
{
    "x" : { "e" : "r" } ,
    "c" : "d"
}
.

+1

看一下sub test:json_input( 0 , 2 ):json_output。

... the prototype is wrong and it never would to work... Let's try.

这是画布或划痕。这个想法。
我现在接受的版本：

sub decorator( $\*&\@\@$$$ ):ATTR {
    my ( undef( ) , $symbol, $referent , undef( ) , $data ) = @_ ;
    my ( $before , $after ) = @$data ;

    *$symbol = sub {
        $after->( $referent->( $before->( @_ ) ) )
    }
}