好吧，这里有一个丑陋的黑客：

# Copy required DLLs to output directory
CONFIG(debug, debug|release) {
    QtCored4.commands = copy /Y %QTDIR%\\bin\\QtCored4.dll debug
    QtCored4.target = debug/QtCored4.dll
    QtGuid4.commands = copy /Y %QTDIR%\\bin\\QtGuid4.dll debug
    QtGuid4.target = debug/QtGuid4.dll

    QMAKE_EXTRA_TARGETS += QtCored4 QtGuid4
    PRE_TARGETDEPS += debug/QtCored4.dll debug/QtGuid4.dll
} else:CONFIG(release, debug|release) {
    QtCore4.commands = copy /Y %QTDIR%\\bin\\QtCore4.dll release
    QtCore4.target = release/QtCore4.dll
    QtGui4.commands = copy /Y %QTDIR%\\bin\\QtGui4.dll release
    QtGui4.target = release/QtGui4.dll

    QMAKE_EXTRA_TARGETS += QtCore4 QtGui4
    PRE_TARGETDEPS += release/QtCore4.dll release/QtGui4.dll
} else {
    error(Unknown set of dependencies.)
}

以下是一些我不喜欢的地方：

• 使用%QTDIR%环境变量;这个变量直到复制命令实际运行时才被计算。看起来沿着QMAKE_LIBS_QT_DLL之类的东西会更合适，但由于某种原因我不能让它工作。
• 硬编码的“调试”和“发布”名称;似乎应该有某种变量来实现。
• 使用“copy”命令调用环境。

我会接受另一个答案，如果有人可以清理这个好一点，例如通过缩短它和/或解决我的一些问题，或只是找到一个更好的方法一般。

一个更干净的方法，但它需要在make之后执行make install。它可以在Windows上工作，但需要在其他平台上进行调整。

debug { DESTDIR = debug }
release { DESTDIR = release }
debug_and_release { DESTDIR = bin }

myqtlibs.path = $$DESTDIR
myqtlibs.files = $$QMAKE_LIBDIR_QT/*.dll junk.txt fred.out
myqtlibs.CONFIG = no_check_exist

INSTALLS += myqtlibs

如果运行qmake只是为了调试，所有输出将进入./debug。如果只是为了发布，所有输出将进入./release。如果两者都是，则进入./bin。
我确实注意到在QtCreator中启用影子构建会导致可执行文件没有在DESTDIR中结束。

使用windeployqt复制依赖

# Deployment - Automatically Detect and Copy Dependencies to Build Folder

TARGET_CUSTOM_EXT = .exe
DEPLOY_COMMAND = windeployqt

DEPLOY_OPTIONS = "--no-svg --no-system-d3d-compiler --no-opengl --no-angle --no-opengl-sw"

CONFIG( debug, debug|release ) {
    # debug
    DEPLOY_TARGET = $$shell_quote($$shell_path($${OUT_PWD}/debug/$${TARGET}$${TARGET_CUSTOM_EXT}))
    DEPLOY_OPTIONS += "--debug"
} else {
    # release
    DEPLOY_TARGET = $$shell_quote($$shell_path($${OUT_PWD}/release/$${TARGET}$${TARGET_CUSTOM_EXT}))
    DEPLOY_OPTIONS += "--release"
}

# Uncomment the following line to help debug the deploy command when running qmake
#message($${DEPLOY_COMMAND} $${DEPLOY_OPTIONS} $${DEPLOY_TARGET})

QMAKE_POST_LINK = $${DEPLOY_COMMAND} $${DEPLOY_OPTIONS} $${DEPLOY_TARGET}

或手动复制依赖

# Deployment - Copy Dependencies to Build Folder

dlls.path  =  $${DESTDIR}
dlls.files += $$[QT_INSTALL_BINS]/icudt51.dll
dlls.files += $$[QT_INSTALL_BINS]/icuin51.dll
dlls.files += $$[QT_INSTALL_BINS]/icuuc51.dll
dlls.files += $$[QT_INSTALL_BINS]/libgcc_s_dw2-1.dll
dlls.files += $$[QT_INSTALL_BINS]/libstdc++-6.dll
dlls.files += $$[QT_INSTALL_BINS]/libwinpthread-1.dll
dlls.files += $$[QT_INSTALL_BINS]/Qt5Core.dll
dlls.files += $$[QT_INSTALL_BINS]/Qt5Network.dll
dlls.files += $$[QT_INSTALL_BINS]/Qt5Gui.dll
dlls.files += $$[QT_INSTALL_BINS]/Qt5Widgets.dll
dllA.path   += $${DESTDIR}/platforms
dllA.files  += $$[QT_INSTALL_PLUGINS]/platforms/qwindows.dll
dllB.path   += $${DESTDIR}/plugins/imageformats/
dllB.files  += $$[QT_INSTALL_PLUGINS]/imageformats/qico.dll
dllB.files  += $$[QT_INSTALL_PLUGINS]/imageformats/qwbmp.dll
INSTALLS   += dlls dllA dllB

引用：http://doc.qt.io/qt-5/qmake-variable-reference.html#deployment
如果你需要识别跨平台的先决条件/依赖项，请看一下CMake的getPrerequisites()。它使用dumpbin，objbin，ldd，otool来识别依赖项。
引用：https://cmake.org/cmake/help/v3.0/module/GetPrerequisites.html

我遇到了同样的问题，jwernerny's solution帮了我很大的忙。但是，我在Window 7上使用的是Shadow Build，它需要更多的tweeking。
我还需要根据当前配置设置DESTDIR。

• 在我的例子中，我想复制*.qml文件 *，这就是我如何实现的：

CONFIG(release, debug|release): DESTDIR = $$OUT_PWD/release
CONFIG(debug, debug|release): DESTDIR = $$OUT_PWD/debug

QmlFiles.path = $$DESTDIR/Qml
QmlFiles.files += $$files(Qml/*.qml)

INSTALLS += QmlFiles

编辑：

因为我使用Shadow Build，所以我需要使用$$OUT_PWD来获取输出文件夹。

一个冗长但清晰的例子：

find_package(Qt5 CONFIG COMPONENTS Widgets REQUIRED)
if (WIN32)
    MESSAGE("Copying dlls...")
    set(QtBin ${Qt5Core_DIR}/../../../bin)
    if (${CMAKE_BUILD_TYPE} STREQUAL Debug)
        file(COPY ${QtBin}/Qt5Cored.dll DESTINATION ${CMAKE_BINARY_DIR})
        file(COPY ${QtBin}/Qt5Widgetsd.dll DESTINATION ${CMAKE_BINARY_DIR})
        file(COPY ${QtBin}/Qt5Guid.dll DESTINATION ${CMAKE_BINARY_DIR})
    else ()
        file(COPY ${QtBin}/Qt5Core.dll DESTINATION ${CMAKE_BINARY_DIR})
        file(COPY ${QtBin}/Qt5Widgets.dll DESTINATION ${CMAKE_BINARY_DIR})
        file(COPY ${QtBin}/Qt5Gui.dll DESTINATION ${CMAKE_BINARY_DIR})
    endif ()
endif ()