我会考虑抛弃复选框，用超链接来代替它们，这些超链接的风格就像复选框一样。这样就可以进行排序，复制和粘贴等，而不会有“漂移”的机会，复选框可以从它们分配的行中分离出来。
用于创建和支持链接的代码（在常规模块中）

'add some hyperlink "checkboxes" to cell in a range
Sub CreateCheckboxes()
    Dim i As Long
    For i = 1 To 20
        AddCheckBox ActiveSheet.Cells(i, "B")
    Next i
End Sub

'Add a "checkbox" to a cell and do some formatting
Sub AddCheckBox(c As Range)
    With c
        .Hyperlinks.Delete
        .Worksheet.Hyperlinks.Add anchor:=c, Address:="#LinkTarget()", _
                                  TextToDisplay:=UncheckedValue
        .Font.Name = "Wingdings"  'this font has the "checkbox" characters 
        .Font.Size = 12           'remove the default blue+underline formatting
        .Font.Underline = False
        .Font.Color = vbBlack
        .HorizontalAlignment = xlCenter
    End With
End Sub

'This serves as a "dummy" destination for the hyperlinks
'  Just returns the clicked-on cell, so the selection doesn't jump around
Function LinkTarget() As Range
    Set LinkTarget = Selection
End Function

'Text for a "checked" cell
'Spaces are just to expand the "clickable" area of the hyperlink
Function CheckedValue() As String
    CheckedValue = " " & Chr(120) & " "
End Function
'Text for an "unchecked" cell
Function UncheckedValue() As String
    UncheckedValue = " " & Chr(111) & " "
End Function
'Is a cell "checked"
Function IsChecked(c As Range) As Boolean
    IsChecked = (c.Value = CheckedValue)
End Function

单击时切换链接外观（工作表代码模块）：

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
    Dim c As Range
    Set c = Target.Range
    
    If c.Column = 2 Then    'if (eg) you need to take some specific action based on where the cell is
        Debug.Print c.Address
        Select Case c.Text  'Toggle cell text
            'You can add code below if some specific action 
            '  to be taken when a checkbox is checked/unchecked.
            'This code just toggles the checkbox appearance
            Case CheckedValue: c.Value = UncheckedValue
            Case UncheckedValue: c.Value = CheckedValue
            Case Else: c.Value = UncheckedValue
        End Select
    End If
End Sub