尝试使用Format函数（这只是示例）并尝试在代码中实现

Sub Test()
    Dim r As Range
    Set r = Range("A1")
    r.Offset(, 3).Value = Format(r.Value, "dd/mm/yyyy")
End Sub

Excel表格（ListObject）

• 以下仅涵盖部分 * 我有一个Excel表格，其中A列的日期格式为mm/dd/year。我想将其更改为dd/mm/year... * 即A列中的值是真实的日期，而不是文本。
• 适当调整图纸和表格名称。
• 由于您处理的是ListObject（表），因此可以考虑使用它的属性。
• 以下过程显示了如何在两种情况下利用其中的一些漏洞。
• 第一个过程将更改表的第一列（不一定是工作表的第一列）中的数字格式。当列始终是第一列时使用该格式，因此可以更改标题（标题）。
• 第二个过程将尝试查找给定的标题（Header）。如果成功，它将对找到标题的列应用数字格式。当标题（标题）永远不会更改，但列在表中的位置可能会更改时，将使用此方法。
  密码

Sub IOnlyKnowTheColumnNumber()
    
    ' The n-th column of the Table, not the worksheet.
    Const DateColumn As Long = 1
    
    Dim wb As Workbook
    Set wb = ThisWorkbook ' The workbook containing this code.
    
    Dim ws As Worksheet
    Set ws = wb.Worksheets("Sheet1")
    
    Dim tbl As ListObject
    Set tbl = ws.ListObjects("Table1")
    
    ' Define Date Column Range ('rng').
    Dim rng As Range
    Set rng = tbl.DataBodyRange.Columns(DateColumn)
    ' Apply formatting to Date Column Range.
    rng.NumberFormat = "dd/mm/yyyy" ' "dd\/mm\/yyyy" for international.

    ' Inform user.
    MsgBox "Number format applied.", vbInformation, "Success"

End Sub

Sub IOnlyKnowTheColumnTitle()
    
    Const Header As String = "Date"
    Dim wb As Workbook
    Set wb = ThisWorkbook ' The workbook containing this code.
    
    Dim ws As Worksheet
    Set ws = wb.Worksheets("Sheet1")
    
    Dim tbl As ListObject
    Set tbl = ws.ListObjects("Table1")
    
    ' Define Header Row Range (Headers, Titles).
    Dim hRng As Range
    Set hRng = tbl.HeaderRowRange
    
    ' Try to calculate the Date Column Number.
    Dim Temp As Variant
    Temp = Application.Match(Header, hRng, 0)
    
    If Not IsError(DateColumn) Then
        ' Define Date Column.
        Dim DateColumn As Long
        DateColumn = CLng(Temp)
        ' Define Date Column Range ('rng').
        Dim rng As Range
        Set rng = tbl.DataBodyRange.Columns(DateColumn)
        ' Apply formatting to Data Column Range.
        rng.NumberFormat = "dd/mm/yyyy" ' "dd\/mm\/yyyy" for international.
        ' Inform user.
        MsgBox "Number format applied.", vbInformation, "Success"
    Else
        ' inform user.
        MsgBox "Could not find '" & Header & "' column.", vbExclamation, "Fail"
    End If

End Sub