任何Excel行的任何单元格（Range）（即使是ListRow）都有Row属性，该属性为1，Column属性应递增以获得以下属性。因此，请尝试理解下一个代码并应用其含义：

Dim Data As Worksheet, addFood As ListObject, AddedRow As listRow, strExisting As String
  
  Set Data = ActiveSheet 'use here the sheet you need
  Set addFood = Data.ListObjects("T_Food")
  
  Set AddedRow = addFood.ListRows.Add()
  With AddedRow
        If Application.CountIf(addFood.DataBodyRange.Columns(1),  Me.txtCode.Text) = 0 Then
            .Range(1, 1) = Me.txtCode.Text
        Else
            strExisting = strExisting & vbCrLf & Me.txtCode.Text
        End If
        If Application.CountIf(addFood.DataBodyRange.Columns(2), Me.txtItemName.Text) = 0 Then
            .Range(1, 2) = Me.txtItemName.Text
        Else
            strExisting = strExisting & vbCrLf & Me.txtItemName.Text
        End If
  End With
  If strExisting <> "" Then MsgBox "The next values already exist in their respective columns:" & vbCrLf & strExisting

编辑：

请尝试理解/使用下一种方法来更改表DataBodyRange中的任何值。如果更方便，您可以直接使用该数字，而不是使用其Header提取列号：

Sub ChangingTableRowsElements()
   Dim Data As Worksheet, addFood As ListObject, findCode As Range
   Dim srcCode As String, changeElem As String, arrCols, ColToBeChanged As String, col
   
   srcCode = Me.txtCode.Text 'the code to be searched for changing
   changeElem = "ToBeChanged" 'the new string value to be placed instead existing
   ColToBeChanged = "Price" 'you should place here A REAL COLUMN HEADER
   
   Set Data = ActiveSheet 'use here the necessary sheet
   Set addFood = Data.ListObjects("T_Food")
   arrCols = addFood.HeaderRowRange.Value 'you may skip this code line if you want supplying the column to be changed number.
   
   Set findCode = addFood.DataBodyRange.Columns(1).Find(what:=srcCode, LookIn:=xlValues, Lookat:=xlWhole, MatchCase:=False) 'find the code to be changed cell
   If Not findCode Is Nothing Then   'the code could be found in the table first column
      col = Application.match(ColToBeChanged, arrCols, 0) 'you may skip this and make col  = 5, meaning the fifth column
      If Not IsError(col) Then
           findCode.Offset(, col - 1).Value = changeElem
      Else
           MsgBox ColToBeChanged & " could not be found between the table headers...": Exit Sub
      End If
   Else
       MsgBox srcCode & " could not be found between the codes in the table first column..."
   End If
End Sub

请在测试后发送一些反馈。