Please try the following solution based on the ideas of John Cappelletti. All credit goes to him.

SQL

-- DDL and sample data population, start
DECLARE @roster TABLE (ID INT PRIMARY KEY, NAME VARCHAR(10), TIME CHAR(4));
INSERT INTO @roster (ID, NAME, TIME) VALUES
(1,'N1','0900'),
(2,'N1','0801')
-- DDL and sample data population, end

DECLARE @source INT = 1
    , @target INT = 2;

SELECT id AS source_id, @target AS target_id
      ,[key] AS [column]
      ,source_Value = MAX( CASE WHEN Src=1 THEN Value END)
      ,target_Value = MAX( CASE WHEN Src=2 THEN Value END)
FROM (
        SELECT Src=1
              ,id 
              ,B.*
         FROM @roster AS A
         CROSS APPLY ( SELECT [Key]
                             ,Value
                       FROM OpenJson( (SELECT A.* For JSON Path,Without_Array_Wrapper,INCLUDE_NULL_VALUES)) 
                     ) AS B
        WHERE id=@source
        UNION ALL
        SELECT Src=2
              ,id = @source
              ,B.*
         FROM @roster AS A
         CROSS APPLY ( SELECT [Key]
                             ,Value
                       FROM OpenJson( (SELECT A.* For JSON Path,Without_Array_Wrapper,INCLUDE_NULL_VALUES)) 
                     ) AS B
         WHERE id=@target
      ) AS A
GROUP BY id, [key]
HAVING MAX(CASE WHEN Src=1 THEN Value END)
     <> MAX(CASE WHEN Src=2 THEN Value END)
    AND [key] <> 'ID'   -- exclude this PK column
ORDER BY id, [key];

Output

+-----------+-----------+--------+--------------+--------------+
| source_id | target_id | column | source_Value | target_Value |
+-----------+-----------+--------+--------------+--------------+
|         1 |         2 | TIME   |         0900 |         0801 |
+-----------+-----------+--------+--------------+--------------+

A general approach here might be to just aggregate over the entire table and report the state of the counts:

SELECT
    CASE WHEN COUNT(DISTINCT ID) = COUNT(*)   THEN 'Yes' ELSE 'No' END AS [ID same],
    CASE WHEN COUNT(DISTINCT NAME) = COUNT(*) THEN 'Yes' ELSE 'No' END AS [NAME same],
    CASE WHEN COUNT(DISTINCT TIME) = COUNT(*) THEN 'Yes' ELSE 'No' END AS [TIME same]
FROM yourTable;

for future searchers - perfect implementation of Yitzhak Khabinsky answer / John Cappelletti idea

with simple usage

sql exec Helper_GetTableRowsDiff 'DBName','TableName','IdColumnName',@FirstId,@secondId

Create PROCEDURE [dbo].[Helper_GetTableRowsDiff] @DatabaseName varchar(100),@TableName varchar(100),@KeyColumnName varchar(100), @compareSourceKey int , @compareDestKey int 
AS
BEGIN
    SET NOCOUNT ON;

declare @compareSourceKeyStr varchar(100) 
set @compareSourceKeyStr =(cast(@compareSourceKey as varchar(100)))
declare @compareDestKeyStr varchar(100) 
set @compareDestKeyStr =(cast(@compareDestKey as varchar(100)))

    declare @sql nvarchar(max) =N'

    if not exists (select top(1) * from '+@DatabaseName+'..'+@TableName+' where '+@KeyColumnName+'='+@compareSourceKeyStr+') 
    begin
        THROW 51000, ''The SOURCE record does not exist in table.'', 1;  
    end
    if not exists (select top(1) * from '+@DatabaseName+'..'+@TableName+' where '+@KeyColumnName+'='+@compareDestKeyStr+') 
    begin
        THROW 51000, ''The DEST record does not exist in table.'', 1;  
    end

    declare @DiffT table ( column_name varchar(100) , source_value varchar(max), dest_value varchar(max) )
insert into @DiffT
        SELECT 
              [key] AS [column]
              ,source_Value = MAX( CASE WHEN Src=1 THEN Value END)
              ,target_Value = MAX( CASE WHEN Src=2 THEN Value END)
        FROM (
                SELECT Src=1,'+@KeyColumnName+' ,B.*
                 FROM '+@DatabaseName+'..'+@TableName+' AS A
                 CROSS APPLY ( SELECT [Key] ,Value
                               FROM OpenJson( (SELECT A.* For JSON Path,Without_Array_Wrapper,INCLUDE_NULL_VALUES)) 
                             ) AS B
                WHERE '+@KeyColumnName+'='+@compareSourceKeyStr+'
                UNION ALL
                SELECT Src=2  ,id = '+@compareSourceKeyStr+'   ,B.*
                 FROM '+@DatabaseName+'..'+@TableName+' AS A
                 CROSS APPLY ( SELECT [Key] ,Value
                               FROM OpenJson( (SELECT A.* For JSON Path,Without_Array_Wrapper,INCLUDE_NULL_VALUES)) 
                             ) AS B
                 WHERE '+@KeyColumnName+'='+@compareDestKeyStr+'
              ) AS A
        GROUP BY '+@KeyColumnName+', [key]
        HAVING MAX(CASE WHEN Src=1 THEN Value END)
             <> MAX(CASE WHEN Src=2 THEN Value END)
            AND [key] <> '''+@KeyColumnName+'''   -- exclude this PK column
        ORDER BY '+@KeyColumnName+', [key];
        '
         set @sql = @sql + ' select * from @difft '

  EXEC sp_ExecuteSQL @sql


END