要使用LONG，你需要PL/SQL。这将把一个LONG列的值放入一个CLOB：

DECLARE
  var_clob clob;
BEGIN
  FOR rec_view IN (SELECT * FROM all_views)
  LOOP
     var_clob := rec_view.text;
  END LOOP;
END;

然后，你可以对CLOB使用所有你想要的字符串操作和/或比较运算符/函数。在此基础上，你可以编写代码来进行你想要做的比较。这是最简单的方法。
如果你想在all_views的顶部创建一个 view，它显示all_views的内容，但TEXT字段是CLOB而不是LONG，你需要dbms_sql来实现这一点。为了在这种情况下将LONG转换为CLOB，你可以使用dbms_lob.createtemporary，在dbms_sql.column_value_long上循环，并使用dbms_lob.append将内容附加到临时CLOB。下面是我的dba_views覆盖视图的摘录，它正是这样做的。作为摘录，它不能按原样使用，但它是一个更大的函数的一部分，该函数操作dbms_sql，但它至少提供了概念：

DECLARE
  var_text_clob clob;
  var_offset pls_integer := 0;
  var_buffer_length pls_integer := 32760;
  var_value_length pls_integer := 0;
  var_long_piece long;
BEGIN
  dbms_lob.createtemporary(var_text_clob, false, dbms_lob.call);
    
  LOOP
    dbms_sql.column_value_long(c => var_cursor,
                               position => 4,
                               length => var_buffer_length,
                               offset => var_offset,
                               value => var_long_piece,
                               value_length => var_value_length);
                               
    EXIT WHEN var_value_length = 0;
    
    dbms_lob.append(var_text_clob, var_long_piece);
    var_offset := var_offset + var_value_length;
  END LOOP;
  
  rec_view.text := var_text_clob;
END;