我不相信这种格式是有文档记录的，但它不太可能改变。相当于

use Scalar::Util qw( blessed refaddr reftype );

my $pkg = blessed($ref);
my $str = sprintf("%s%s(0x%x)",
   ( defined($pkg) ? "$pkg=" : "" ),
   reftype($ref),
   refaddr($ref),
);

如果你想要Perl对引用的字符串化的组件，你可以使用blessed、reftype和refaddr，但是下面是获得Perl对引用的字符串化的最佳方法：

use overload qw( );

my $str = overload::StrVal($ref);

没关系，当然，在我发布这篇文章后的一分钟，我找到了答案：

overload::StrVal($o)

(see也停止perl重载或打印内存“地址”的引用）

一种基于对象的数据（属性）对对象进行字符串化的方法

package ClassStringify;

use warnings;
use strict;

sub new {
    my ($class, %args) = @_; 
    return bless { %args }, $class; 
}

use overload  q("") => sub { 
    my $self = shift; 
    return exists $self->{name} ? $self->stringify() : $self;
};

sub stringify {
    my $self = shift;
    return join "\n", map { "$_ => $self->{$_}" } keys %$self;
}

1;

关于Main

use warnings;
use strict;
use feature 'say';

use ClassStringify;

say ClassStringify->new( name => 'obj_name', id => 123 );
say '---';    
say ClassStringify->new( id => 123 );

什么指纹

name => obj_name
id => 123
---
ClassStringify=HASH(0x23b62c8)

对于所需的打印格式

use overload  q("") => sub { 
    my $self = shift; 
    return exists $self->{name} ? $self->stringify('name') : $self;   
};

sub stringify {
    my ($self, $attr) = @_; 
    return ref($self) . " ($attr=$self->{$attr})";
}

这个打印

ClassStringify (name=obj_name)
---
ClassStringify=HASH(0x22852c8)