是的，即使10年了，SDI仍然令XLAM开发人员感到沮丧。我也看到了“消失”的用户表单，并做了一些修改，使之工作。我注意到的一件事是，当我在任务栏中的Excel缩略图上悬停时，用户表单会出现在我的第二个显示器的边缘，所以我知道它已经加载，但只是不可见。SetParent的使用在某种程度上工作得很好，问题似乎是关于用户表单定位的。当用户表单有了一个新的父级时，它就不再是真正的无模式的了（如果你将它滑向工作簿的边缘，你会看到它位于窗口中，而不是在窗口上方）。父母的改变也会打乱坐标系，但不是以一种有意义的方式。我希望事情是相对于活动窗口的，但事实并非如此。设置userform.left似乎基本上被忽略了，它报告了一些奇怪的数字（这些数字在这个例子中显示在状态栏中，当你离开主显示器时，你会看到它们超过了你的总水平分辨率）。
这并不完美：positionUserForm在我的主显示器上可靠地工作，尽管即使在主显示器上，位置也不像预期的那样一致。当我将一个工作簿移出主显示器时，由于xCoordinate超出了可见空间，当切换到时，窗体停止显示。我希望进一步的API与设备上下文的争论将需要完全正确。
除了状态栏更新之外，我还在一个标准模块中添加了两个变量（hwndUserForm和objUserForm），用于传递用户表单，这样我就不会在类中使用硬编码字符串，并且我让类进行表单定位，这样您就可以从表单切换窗口，或者只需单击另一个打开的窗口即可。希望这能送你回家。

'''' Class WinActivate
Public WithEvents AppEvents As Application
Private Declare PtrSafe Function SetParent Lib "user32" _
   (ByVal hWndChild As LongPtr, ByVal hWndNewParent As LongPtr) As LongPtr

Private Sub AppEvents_WindowActivate(ByVal wb As Workbook, ByVal Wn As Window)
    'Change precedent object of UserForm when switching windows
    'hwndUserForm is a global that is set when a userform is loaded and set to 0 when it's unloaded
    If Val(Application.Version) >= 15 And hwndUserForm <> 0 Then
        SetParent hwndUserForm, Wn.hwnd
        positionUserForm objUserForm
    End If
End sub

''''Standard Module
Option Explicit
Dim WA As New WinActivate
Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" _
  (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr

Public hwndUserForm   As Long 'handle to userform, used by WinActivate class, set by showModeless, set to 0 where you unload the form
Public objUserForm As Object 'userform object, set where userform is loaded and before calling showModeless, destroyed where you unload the userform

Sub ShowModeless()
    Set WA.AppEvents = Application
    objUserForm.Show 0
End Sub

Sub load_test_form()
    Load frm_test
    Set objUserForm = frm_test
    hwndUserForm = FindWindow("ThunderDFrame", objUserForm.Caption)
    positionUserForm objUserForm
    ShowModeless
End Sub
Public Sub positionUserForm(ByRef thisform As Object)
    If thisform Is Nothing Then Exit Sub
    thisform.Left = 100
    thisform.Top = 100
    Application.StatusBar = UCase(Left(thisform.Caption, 2)) & " fLeft: " & thisform.Left & " | wLeft: " & ActiveWindow.Left & " | " & ActiveWindow.Caption & " " & thisform.Caption
End Sub

''''userform code
Option Explicit
Private initializing As Boolean
Private Sub cbx_file2_Change()
    If initializing Then Exit Sub
    Application.Workbooks(Me.cbx_file2.Text).Activate
End Sub
Private Sub cbx_file1_Change()
    If initializing Then Exit Sub
    Application.Workbooks(Me.cbx_file1.Text).Activate
End Sub
Private Sub UserForm_Initialize()
Dim wb As Workbook
Dim i As Integer
    initializing = True
    If Application.Workbooks.Count = 0 Then
        MsgBox "This requires at least one open workbook", vbInformation, "Workbook Required"
        Exit Sub
    End If
    
    For Each wb In Application.Workbooks
        Me.cbx_file1.AddItem
        Me.cbx_file1.List(Me.cbx_file1.ListCount - 1, 0) = wb.Name
        If cbx_file1.List(Me.cbx_file1.ListCount - 1, 0) = ActiveWorkbook.Name Then
            Me.cbx_file1.ListIndex = Me.cbx_file1.ListCount - 1
        End If
    Next wb
   
    Me.cbx_file2.List = Me.cbx_file1.List
    If Me.cbx_file2.ListCount > 0 Then
        For i = 0 To Me.cbx_file2.ListCount - 1
            If i <> Me.cbx_file1.ListIndex Then
                Me.cbx_file2.ListIndex = i
                Exit For
            End If
        Next i
    End If
    initializing = False
End Sub