这也可以使用Windows Excel 2010+和Excel 365（Windows或Mac）中提供的Power Query来完成
使用Power Query

• 选择数据表中的某个单元格
• Data => Get&Transform => from Table/Range
• PQ编辑器打开时：Home => Advanced Editor
• 记下第2行中的表名称
• 将下面的M代码粘贴到您所看到的位置
• 将第2行中的Table名称更改回最初生成的名称。
• 阅读评论并探索Applied Steps以了解算法

let

//Change next line to reflect actual data source
    Source = Excel.CurrentWorkbook(){[Name="Table21"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Country", type text}, {"Gender", type text}}),

//Add columns with a list of Hobbys and Teams
    #"Add Hobby" = Table.AddColumn(#"Changed Type", "Hobby", 
        each {"Sleep","Run","Play"}),
        
    #"Add Team" = Table.AddColumn(#"Add Hobby", "Team", 
        each {"Red","Blue"}),

//Expand the lists to new rows
    #"Expanded Hobby" = Table.ExpandListColumn(#"Add Team", "Hobby"),
    #"Expanded Team" = Table.ExpandListColumn(#"Expanded Hobby", "Team"),

//Sort to get to your posted order (or omit this step if you want
    #"Sorted Rows" = Table.Sort(#"Expanded Team",{
        {"Hobby", Order.Descending}, 
        {"Team", Order.Descending}, 
        {"Gender", Order.Descending}})
in
    #"Sorted Rows"