使用行填充组合框

Sub PopulateCombobox()

    Const MatchString As String = "price"
     
    Dim ws As Worksheet: Set ws = ThisWorkbook.ActiveSheet ' improve!

    Dim hData():
    hData = ws.Range("A1", ws.Range("A1").End(xlToRight)).Value ' or .Value2
    
    Dim sc As Long, dc As Long, HeaderString As String
    
    For sc = 1 To UBound(hData, 2)
        HeaderString = CStr(hData(1, sc))
        If InStr(1, HeaderString, MatchString, vbTextCompare) > 0 Then
            dc = dc + 1
            hData(1, dc) = hData(1, sc)
        End If
    Next sc
    
    If dc = 0 Then
        MsgBox "No headers containing """ & MatchString & """ found.", _
            vbCritical
        Exit Sub
    End If
    
    If dc < sc - 1 Then
        ReDim Preserve hData(1 To 1, 1 To dc)
    'Else ' all columns contain the match string; do nothing
    End If
    
    With Me.ComboBox1
        ' Populate column:
        .List = Application.Transpose(hData)
        ' or populate row (probably a bad idea):
        '.ColumnCount = dc
        '.List = hData
    End With
    
End Sub

正如@VBasic2008所指出的，Filter（）需要一个一维数组。因此，您可以通过转置两次将header_arr转换为一维数组。然后，一旦筛选了数组，就可以简单地使用组合框的List属性来分配筛选后的数组。
请注意以下内容。。

1. filtered_arr已被声明为动态String数组，尽管它可以被声明为Variant。
   1.已指定目标工作表，请相应地更改名称。
   这是密码...

Private Sub UserForm_Initialize()

    Dim header_arr() As Variant
    Dim filtered_arr() As String
    Dim ws As Worksheet
    
    Set ws = ThisWorkbook.Worksheets("Sheet1") 'change the sheet name accordingly

    header_arr = ws.Range(Cells(1, 1), Cells(1, 1).End(xlToRight)).Value2
    
    With Application
        header_arr = .Transpose(.Transpose(header_arr))
    End With

    filtered_arr = Filter(header_arr, "price", True, vbTextCompare)
    
    Me.ComboBox1.List = filtered_arr

End Sub