Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
    If Sh Is LstSht Then
        If ThisWorkbook.Sheets.Count > 1 Then
            Set LstSht = ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count)
        Else
            Set LstSht = Nothing
        End If
    End If
End Sub

在此代码中，我们首先确定停用的表（Sh）和LstSht是否相同。如果它们是相同的，我们检查工作簿中是否还有其他工作表。如果是，我们使用ThisWorkbook.Sheets（ThisWorkbook.Sheets.Count）将LstSht设置为最后一个工作表。否则，如果只剩下一个工作表或根本没有工作表，则将LstSht设置为Nothing。

您的代码表明您希望具有对上一个活动工作表的引用。但是如果删除了this，这个引用必须变成Nothing，这样在代码的其他部分它就会被检查而不会被使用。这可以与另一个事件一起完成：
复制模块中的下一个代码（供常用）

Option Explicit

Public justDeactivatedSheet As Worksheet 'the variable you name LstSht
Public justDeletedSheet As Worksheet

复制ThisWorkBook模块中的下一段代码：

Option Explicit

'ON SHEET DELETION THIS IS EXECUTING FIRST
Private Sub Workbook_SheetBeforeDelete(ByVal Sh As Object)
   Set justDeletedSheet = Sh
   MsgBox ("Workbook_SheetBeforeDelete " & Sh.Name)
End Sub

'ON SHEET DELETION THIS IS EXECUTING AFTER Workbook_SheetBeforeDelete
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
   If Not justDeletedSheet Is Nothing Then
      If justDeletedSheet Is Sh Then
         MsgBox ("deactivate the deleted >" & vbCrLf & _
                 "Set justDeactivatedSheet = Nothing" & vbCrLf & _
                 "Set justDeletedSheet = Nothing")
         Set justDeactivatedSheet = Nothing
         Set justDeletedSheet = Nothing
      Else
         Set justDeactivatedSheet = Sh
      End If
   Else
      Set justDeactivatedSheet = Sh
   End If
End Sub

并复制一个使用justDeactivatedSheet的示例，
在表单模块中。在我的例子中，我使用了一个按钮的click事件

Option Explicit

Private Sub CommandButton1_Click()
'in your code have to check, eg
   If Not justDeactivatedSheet Is Nothing Then
      If Not ActiveSheet Is justDeactivatedSheet Then
         MsgBox ("the previus active sheet was the " _
                  & justDeactivatedSheet.Name)
      End If
   Else
      MsgBox ("The justDeactivatedSheet is NOTHING ")
   End If
End Sub