在CMD批处理文件中，我可以确定它是否是从powershell运行的吗？

dvtswwa3  于 2023-08-05  发布在  Shell
关注(0)|答案(4)|浏览(127)

我有一个Windows批处理文件，其目的是设置一些环境变量，例如。

=== MyFile.cmd ===
SET MyEnvVariable=MyValue

字符串
用户可以在执行需要环境变量的工作之前运行此命令，例如：

C:\> MyFile.cmd
C:\> echo "%MyEnvVariable%"    <-- outputs "MyValue"
C:\> ... do work that needs the environment variable

型
这大致相当于Visual Studio安装的“开发人员命令提示符”快捷方式，它设置了运行VS实用程序所需的环境变量。
但是，如果用户碰巧打开了Powershell提示符，环境变量当然不会传播回Powershell：

PS C:\> MyFile.cmd
PS C:\> Write-Output "${env:MyEnvVariable}"  # Outputs an empty string

型
这可能会让在CMD和PowerShell之间切换的用户感到困惑。
有没有一种方法可以在我的批处理文件MyFile.cmd中检测到它是从PowerShell调用的，这样我就可以，例如，向用户显示警告？这需要在没有任何第三方实用程序的情况下完成。

powershell

4条答案

按热度按时间
flmtquvp

flmtquvp1#

Your own answer is robust，虽然由于需要运行PowerShell进程而通常较慢，但可以通过优化用于确定调用shell的PowerShell命令来显著加快速度：

@echo off
setlocal
CALL :GETPARENT PARENT
IF /I "%PARENT%" == "powershell" GOTO :ISPOWERSHELL
IF /I "%PARENT%" == "pwsh" GOTO :ISPOWERSHELL
endlocal

echo Not running from Powershell 
SET MyEnvVariable=MyValue

GOTO :EOF

:GETPARENT
SET "PSCMD=$ppid=$pid;while($i++ -lt 3 -and ($ppid=(Get-CimInstance Win32_Process -Filter ('ProcessID='+$ppid)).ParentProcessId)) {}; (Get-Process -EA Ignore -ID $ppid).Name"

for /f "tokens=*" %%i in ('powershell -noprofile -command "%PSCMD%"') do SET %1=%%i

GOTO :EOF

:ISPOWERSHELL
echo. >&2
echo ERROR: This batch file must not be run from a PowerShell prompt >&2
echo. >&2
exit /b 1

字符串
在我的机器上，这运行速度大约快3 - 4倍（YMMV）-但仍然需要几乎1秒钟。
请注意，我还添加了对进程名pwsh的检查，以便使解决方案也能与PowerShell Core 一起工作。

更快的替代方案-尽管不太稳健：

下面的解决方案依赖于以下假设，默认安装为真：
只有一个名为PSModulePath的 system 环境变量被持久地定义在注册表中（也不是一个 * 用户特定的 * 环境变量）。
该解决方案依赖于检测PSModulePath中是否存在用户特定的路径，PowerShell在启动时会自动添加该路径。

@echo off
echo %PSModulePath% | findstr %USERPROFILE% >NUL
IF %ERRORLEVEL% EQU 0 goto :ISPOWERSHELL

echo Not running from Powershell 
SET MyEnvVariable=MyValue

GOTO :EOF

:ISPOWERSHELL
echo. >&2
echo ERROR: This batch file must not be run from a PowerShell prompt >&2
echo. >&2
exit /b 1

型

按需启动新cmd.exe控制台窗口的替代方法：

在前面的方法的基础上，下面的变体只是在检测到批处理文件正在从PowerShell运行时 * 在新的cmd.exe窗口 * 中重新调用批处理文件**。
这不仅对用户更方便，而且还减轻了上述解决方案产生假阳性的问题：当从 * 从PowerShell* 启动的交互式cmd.exe会话运行时，上述解决方案将拒绝运行，即使它们应该运行，正如PetSerAl所指出的那样。
虽然下面的解决方案本身也没有检测到这种情况，但它仍然打开了一个可用的（尽管是新的）窗口，其中设置了环境变量。

@echo off
REM # Unless already being reinvoked via cmd.exe, see if the batch
REM # file is being run from PowerShell.
IF NOT %1.==_isNew. echo %PSModulePath% | findstr %USERPROFILE% >NUL
REM # If so, RE-INVOKE this batch file in a NEW cmd.exe console WINDOW.
IF NOT %1.==_isNew. IF %ERRORLEVEL% EQU 0 start "With Environment" "%~f0" _isNew & goto :EOF

echo Running from cmd.exe, setting environment variables...

REM # Set environment variables.
SET MyEnvVariable=MyValue

REM # If the batch file had to be reinvoked because it was run from PowerShell,
REM # but you want the user to retain the PowerShell experience,
REM # restart PowerShell now, after definining the env. variables.
IF %1.==_isNew. powershell.exe

GOTO :EOF

型
设置所有环境变量后，请注意最后一个IF语句也是如何重新调用PowerShell的，但在 * 相同 * 的新窗口中，基于调用用户更喜欢在PowerShell中工作的假设。
然后，新的PowerShell会话将看到新定义的环境变量，但请注意，您需要 * 两个 * 连续的exit调用来关闭窗口。

赞(0）分享  回复(0）举报  2023-08-05
3vpjnl9f

3vpjnl9f2#

就像乔·科克常说的：“我靠朋友的一点帮助过日子。”
在这个例子中，来自Lieven Keersmaekers，他的评论使我得到了以下解决方案：

@echo off
setlocal
CALL :GETPARENT PARENT
IF /I "%PARENT%" == "powershell.exe" GOTO :ISPOWERSHELL
endlocal

echo Not running from Powershell 
SET MyEnvVariable=MyValue

GOTO :EOF

:GETPARENT
SET CMD=$processes = gwmi win32_process; $me = $processes ^| where {$_.ProcessId -eq $pid}; $parent = $processes ^| where {$_.ProcessId -eq $me.ParentProcessId} ; $grandParent = $processes ^| where {$_.ProcessId -eq $parent.ParentProcessId}; $greatGrandParent = $processes ^| where {$_.ProcessId -eq $grandParent.ParentProcessId}; Write-Output $greatGrandParent.Name

for /f "tokens=*" %%i in ('powershell -command "%CMD%"') do SET %1=%%i

GOTO :EOF

:ISPOWERSHELL
echo.
echo ERROR: This batch file may not be run from a PowerShell prompt
echo.
cmd /c "exit 1"
GOTO :EOF

字符串

赞(0）分享  回复(0）举报  2023-08-05
nmpmafwu

nmpmafwu3#

我为Chocolatey的RefreshEnv.cmd脚本做了这样的事情：Make refreshenv.bat error if powershell.exe is being used。
由于不相关的原因，我的解决方案最终没有被使用，但它可以在这个repo中使用：beatcracker/detect-batch-subshell。这是它的副本，以防万一。

仅在从交互式命令处理器会话直接调用时运行的脚本

脚本将检测它是否从非交互式会话（cmd.exe /c detect-batch-subshell.cmd）运行，并显示相应的错误消息。
非交互式shell包括PowerShell/PowerShell伊势、Explorer等。基本上，任何试图通过在单独的cmd.exe示例中运行脚本来执行脚本的东西。
然而，从PowerShell/PowerShell伊势进入cmd.exe会话并在那里执行脚本将起作用。

依赖关系

  • wmic.exe-随Windows XP Professional及更高版本提供。

示例：

1.打开cmd.exe
1.型号detect-batch-subshell.cmd

输出：

> detect-batch-subshell.cmd

Running interactively in cmd.exe session.

字符串

示例：

1.打开powershell.exe
1.型号detect-batch-subshell.cmd

输出：

PS > detect-batch-subshell.cmd

detect-batch-subshell.cmd only works if run directly from cmd.exe!

型

代码

  • detect-batch-subshell.cmd个
@echo off

setlocal EnableDelayedExpansion

:: Dequote path to command processor and this script path
set ScriptPath=%~0
set CmdPath=%COMSPEC:"=%

:: Get command processor filename and filename with extension
for %%c in (!CmdPath!) do (
    set CmdExeName=%%~nxc
    set CmdName=%%~nc
)

:: Get this process' PID
:: Adapted from: http://www.dostips.com/forum/viewtopic.php?p=22675#p22675
set "uid="
for /l %%i in (1 1 128) do (
    set /a "bit=!random!&1"
    set "uid=!uid!!bit!"
)

for /f "tokens=2 delims==" %%i in (
    'wmic Process WHERE "Name='!CmdExeName!' AND CommandLine LIKE '%%!uid!%%'" GET ParentProcessID /value'
) do (
    rem Get commandline of parent
    for /f "tokens=1,2,*" %%j in (
        'wmic Process WHERE "Handle='%%i'" GET CommandLine /value'
    ) do (

        rem Strip extra CR's from wmic output
        rem http://www.dostips.com/forum/viewtopic.php?t=4266
        for /f "delims=" %%x in ("%%l") do (
            rem Dequote path to batch file, if any (3rd argument)
            set ParentScriptPath=%%x
            set ParentScriptPath=!ParentScriptPath:"=!
        )

        rem Get parent process path
        for /f "tokens=2 delims==" %%y in ("%%j") do (
            rem Dequote parent path
            set ParentPath=%%y
            set ParentPath=!ParentPath:"=!

            rem Handle different invocations: C:\Windows\system32\cmd.exe , cmd.exe , cmd
            for %%p in (!CmdPath! !CmdExeName! !CmdName!) do (
                if !ParentPath!==%%p set IsCmdParent=1
            )

            rem Check if we're running in cmd.exe with /c switch and this script path as argument
            if !IsCmdParent!==1 if %%k==/c if "!ParentScriptPath!"=="%ScriptPath%" set IsExternal=1
        )
    )
)

if !IsExternal!==1 (
    echo %~nx0 only works if run directly from !CmdExeName!^^!
    exit 1
) else (
     echo Running interactively in !CmdExeName! session.
 )

endlocal

型

赞(0）分享  回复(0）举报  2023-08-05
ejk8hzay

ejk8hzay4#

就像beatcracker的答案一样，我认为最好不要对可用于启动批处理脚本的外部shell进行假设，例如，通过bash shell运行批处理文件时也会出现问题。
因为它只使用CMD的本机工具，不依赖于任何外部工具或WMI，所以执行时间非常快。

@echo off
call :IsInvokedInternally && (
    echo Script is launched from an interactive CMD shell or from another batch script.
) || (
    echo Script is invoked by an external App. [PowerShell, BASH, Explorer, CMD /C, ...]
)
exit /b

:IsInvokedInternally
setlocal EnableDelayedExpansion
:: Getting substrings from the special variable CMDCMDLINE,
:: will modify the actual Command Line value of the CMD Process!
:: So it should be saved in to another variable before applying substring operations.
:: Removing consecutive double quotes eg. %systemRoot%\system32\cmd.exe /c ""script.bat""
set "SavedCmdLine=!cmdcmdline!"
set "SavedCmdLine=!SavedCmdLine:""="!"
set /a "DoLoop=1, IsExternal=0"
set "IsCommand="
for %%A in (!SavedCmdLine!) do if defined DoLoop (
    if not defined IsCommand (
        REM Searching for /C switch, everything after that, is CMD commands
        if /i "%%A"=="/C" (
            set "IsCommand=1"
        ) else if /i "%%A"=="/K" (
            REM Invoking the script with /K switch creates an interactive CMD session
            REM So it will be considered an internal invocatoin
            set "DoLoop="
        )
    ) else (
        REM Only check the first command token to see if it references this script
        set "DoLoop="

        REM Turning delayed expansion off to prevent corruption of file paths
        REM which may contain the Exclamation Point (!)
        REM It is safe to do a SETLOCAL here because the we have disabled the Loop,
        REM and the routine will be terminated afterwards.
        setlocal DisableDelayedExpansion
        if /i "%%~fA"=="%~f0" (
            set "IsExternal=1"
        ) else if /i "%%~fA"=="%~dpn0" (
            set "IsExternal=1"
        )
    )
)
:: A non-zero ErrorLevel means the script is not launched from within CMD.
exit /b %IsExternal%

字符串
它检查用于启动CMD shell的命令行，以判断脚本是从CMD内部启动的，还是由外部应用程序使用命令行签名/C script.bat启动的，/C script.bat通常由非CMD shell用于启动批处理脚本。
如果出于任何原因需要绕过外部启动检测，例如当使用其他命令手动启动脚本以利用定义的变量时，可以通过在CMD命令行中将@前置到脚本的路径来完成：

cmd /c @MyScript.bat & AdditionalCommands

型

赞(0）分享  回复(0）举报  2023-08-05
我来回答

相关问题

    查看更多

    热门标签

    更多
    JavaquerypythonNode开发语言requestUtil数据库Table后端算法LoggerMessageElementParser

    最新问答

    更多
    • 蜀ICP备13028337号-1 大数据知识库 https://www.saoniuhuo.com © All rights reserved
    • 本站内容来源互联网,如果侵犯您的权益请联系我们删除, 联系方式：448109455@qq.com