假设此数据

下面的代码

Option Explicit

Public Sub DoSomeStuff()
    
    ' get selection so we know where to start
    Dim SelRng As Range
    On Error Resume Next
    Set SelRng = Application.InputBox(Title:="Please select a range", Prompt:="Select range", Type:=8)
    On Error GoTo 0
    If SelRng Is Nothing Then Exit Sub
    
    ' find out which sheet we are working with
    Dim ws As Worksheet
    Set ws = SelRng.Parent
    
    ' get last used row left of the selection
    Dim LastRow As Long
    LastRow = ws.Cells(ws.Rows.Count, SelRng.Column - 1).End(xlUp).Row

    ' get the data range left of the selection
    Dim DataRange As Range
    Set DataRange = SelRng.Offset(ColumnOffset:=-1).Resize(LastRow - SelRng.Row + 1)
    
    
    ' here we collect all rows that will be deleted
    Dim RowsToDelete As Range
    
    ' loop through all cells in the data range
    Dim Cell As Variant
    For Each Cell In DataRange.Cells
        ' if value is zero add the row to RowsToDelete
        If Cell.Value = 0 Then
            If RowsToDelete Is Nothing Then
                Set RowsToDelete = Cell.EntireRow
            Else
                Set RowsToDelete = Application.Union(RowsToDelete, Cell.EntireRow)
            End If
        End If
    Next Cell
    
    ' if RowsToDelete were found then delete them
    If Not RowsToDelete Is Nothing Then
        RowsToDelete.Delete
    End If
    
    ' get again the last used row (because we deleted rows it's less)
    LastRow = ws.Cells(ws.Rows.Count, SelRng.Column - 1).End(xlUp).Row
    
    ' write the numeric date into the first cell
    SelRng.Value = Now()
    SelRng.NumberFormat = "YYMMDD" 'format the date
    
    ' fill down
    SelRng.AutoFill ws.Range(SelRng, ws.Cells(LastRow, SelRng.Column))
End Sub

字符串
会把它变成

我强烈建议不要使用dtToday = Format(Date, "yymmdd")将日期写入单元格，因为Format将返回一个看起来像日期的文本String。但这不再是一个日期，所以你不能用它来计算。始终使用数字日期，如SelRng.Value = Now()或Date()，然后使用NumberFormat。这样，它保持一个数字日期，您可以计算，您可以轻松地改变格式，每当需要的。