我不能帮助你定位传感器组件，因为我只在我第一次Android开发的早期尝试过它。但是，您可以使用API实现GPS功能。在应用程序“稳定”并且UI变为活动状态之前，不要调用StartAndroidGps。例如，用户登录后。

uses
  , Androidapi.JNI.Provider
  , Androidapi.JNI.JavaTypes
  , Androidapi.Helpers
  , Androidapi.JNI.Location
  , Androidapi.JNIBridge
  , FMX.Helpers.Android
  , Androidapi.JNI.GraphicsContentViewText
  , Androidapi.JNI.Net
  , AndroidApi.JNI.Embarcadero
  , Androidapi.JNI.Os
  , System.Android.Sensors 
  , System.Android.Service

private
    FLocationManager : JLocationManager;
    locationListener : TLocationListener;
    procedure LocationisChanged(location: JLocation);
    procedure StartAndroidApi;
    procedure StopAndroidApi;

  TLocationListener = class(TJavaLocal, JLocationListener)
  private
    [weak]
    FParent : TfrmTabbed;
  public
    constructor Create(AParent : TfrmTabbed);
    procedure onLocationChanged(location: JLocation); cdecl;
    procedure onProviderDisabled(provider: JString); cdecl;
    procedure onProviderEnabled(provider: JString); cdecl;
    procedure onStatusChanged(provider: JString; status: Integer; extras: JBundle); cdecl;
  end;

...

procedure TfrmTabbed.StartAndroidGPS;
var
  LocationManagerService: JObject;
  location : JLocation;
begin

  if not Assigned(FLocationManager) then
  begin
    LocationManagerService := TAndroidHelper.Context.getSystemService(TJContext.JavaClass.LOCATION_SERVICE);
    FLocationManager := TJLocationManager.Wrap((LocationManagerService as ILocalObject).GetObjectID);
    if not Assigned(locationListener) then
      locationListener := TLocationListener.Create(self);
  end;

  FLocationManager.requestLocationUpdates(TJLocationManager.JavaClass.GPS_PROVIDER,
      15000, 30, locationListener,
        TJLooper.JavaClass.getMainLooper); // see the Android doc's

  // just to get started, ask for Last Known Location if any
  LogMe('GPS started');
  location := FLocationManager.getLastKnownLocation(TJLocationManager.JavaClass.GPS_PROVIDER);
  LocationisChanged(location);

end;

procedure TfrmTabbed.StopAndroidGPS;
begin
  LogMe('GPS stopped');
  if Assigned(locationListener) then
    FLocationManager.removeUpdates(locationListener);
end;

{ TLocationListener }

constructor TLocationListener.Create(AParent: TfrmTabbed);
begin
  inherited Create;
  FParent := AParent;
end;

procedure TLocationListener.onLocationChanged(location: JLocation);
begin
  FParent.LocationisChanged(location);
end;

procedure TLocationListener.onProviderDisabled(provider: JString);
begin
end;

procedure TLocationListener.onProviderEnabled(provider: JString);
begin
end;

procedure TLocationListener.onStatusChanged(provider: JString; status: Integer;
  extras: JBundle);
begin
end;

procedure TfrmTabbed.LocationisChanged(location: JLocation);
begin

  if FisClosing then
    EXIT; // the code causes an AV if the app is already closing

  if Assigned(location) then
  begin
    // Calling the LocationSensor's method :-)
    LocationSensor1LocationChanged(Self,
      TLocationCoord2D.Create(0,0),
      TLocationCoord2D.Create(location.getLatitude, location.getLongitude))
  end;

end;