在这个片段中：

main :: IO ()
main = do
    for [0..12] $ \x -> do
        let i = (1 + (x * 3))
            j = (60 - (x * 5)) in
            printf "I=%d J=%d\n" i j :: IO ()

这里没有明确指出使用的是哪种数值类型。这将检查是否为0，12等。是Int s，Integer s，Word64 s，Double s或Complex。
在某些有限的情况下，GHC会将未知的数值类型“默认”为Integer或Double，这取决于它的使用方式，但这依赖于未知类型被约束到一组有限的“内置”类型类，而printf的使用引入了一个额外的类型类约束，干扰了这个默认过程。如果避免使用printf，则默认类型将按预期工作，因此以下工作（数字类型默认为Integer）：

import Text.Printf

for list action = mapM_ action list

main :: IO ()
main = do
    for [0..12] $ \x -> do
        let i = (1 + (x * 3))
            j = (60 - (x * 5)) in
            putStrLn $ "I=" ++ show i ++ " J=" ++ show j

或者，如果你添加一个类型签名来显式地指示你想要使用的数值类型，它也可以工作：

import Text.Printf

for list action = mapM_ action list

main :: IO ()
main = do
    for [(0::Int)..12] $ \x -> do
    --     ^^^^^
        let i = (1 + (x * 3))
            j = (60 - (x * 5)) in
            printf "I=%d J=%d\n" i j :: IO ()

你也可以在let语句中给予类型签名，所以这也可以工作：

import Text.Printf

for list action = mapM_ action list

main :: IO ()
main = do
    for [0..12] $ \x -> do
        let i, j :: Int
        --  ^^^^^^^^^^^
            i = (1 + (x * 3))
            j = (60 - (x * 5)) in
            printf "I=%d J=%d\n" i j :: IO ()

基本上，任何让GHC找出类型的东西都会修复这个错误。您使用block的版本能够正常工作的原因是block具有将数值类型确定为Int的类型签名。如果你忽略了这个类型签名，你会得到同样的错误：

import Text.Printf

for list action = mapM_ action list

-- comment out the type signature, and it fails
-- block :: Int -> IO ()
block x = 
    let i = 1 + (x * 3)
        j = 60 - (x * 5) in
        printf "I=%d J=%d\n" i j :: IO ()

main :: IO ()
main = do
    for [0..12] $ \x -> do block x