你只需要在summarize之后使用extend，并创建allVM字段的子字符串，我想我有你的KQL在这里：

Table
| where type == "TYPE"
| summarize
    lastEventTime = arg_max(lastEvent, *),
    vmCount = count(),
    onboardedCount = countif(onboarded), 
    failVM = make_list_if(entity, onboarded == false and isnotempty(entity)),
    allVM = make_set(entity)
    by environmentType, osType, id, type
| extend allVM1 = substring(allVM, 0, 100)
| extend allVM2 = substring(allVM, 100, 9999)

array_slice could be just the thing you're looking for.
I've edited your example code a little, hopefully though it's transferable enough to your use case. I've removed lastEventTime , and id .

let T = materialize(range Position from 1 to 500 step 1 //Generate a random-ish entity table
| extend entity = rand(1000)
| where  entity < 500 //Generate random number of results to output
| extend type = 'TYPE'
| extend onboarded = iif(rand(1000) < 500, true, false)
| extend osType = case(
  rand(1000) < 500, 'Windows 11',
  rand(1000) < 500, 'Windows 10',
  rand(1000) < 500, 'Server 2019',
  rand(1000) < 500, 'Server 2022',
  'Microsoft Bob'
  )
);
T
| where type == 'TYPE'
| summarize vmCount = count(), onboardedCount = countif(onboarded), 
  failVM = make_list_if(entity, onboarded == false and isnotempty(entity)),
  allVM = make_set(entity)
  by osType, type
| extend allVM1 = array_slice(allVM, 0, 99) //Take the beginning (0) and slide to 100 (99)
| extend allVM2 = array_slice(allVM, 100, -1) //Take from 101 to the end

有很多方法可以实现这一点，因为已经有一些答案，我将提供另一种方法（您可以对https://help.kusto.windows.net/ContosoSales执行）：

SalesTable
| take 1000
| sort by City
| extend row=row_number()
| summarize Under100=make_list_if(SalesAmount, row  <= 100), Over=make_list_if(SalesAmount, row > 100)

关键的思想是给用户row_number()，其中指定一个数字按照一个排序，然后使用一个条件函数（有很多以_if结尾），在此我使用make_list_if
如果你不想排序，你可以以任何你想要的条件...