您可以通过两个步骤来实现这一点-首先动态生成查询，然后执行它：
1.生成查询：

let T = datatable (Service:string, ['201']:long, ['202']:long, ['401']:long)
[
    "A", 100, 50, 20, 
    "C", 25, 0, 0
];
T | getschema 
| where ColumnName != "Service"
| extend Column = bin(tolong(ColumnName), 100)
| summarize make_list(strcat("['", ColumnName, "']")) by Column
| project strcat("['", Column/100, "xxCount'] = ", strcat_array(list_, " + "))
| summarize ExtendedColumns = strcat_array(make_list(Column1), ", ")

| ExtendedColumns|
| --|
| “2xxCount”] =“201”] +“202”]，“4xxCount”] =“401”]|
1.运行它：

let T = datatable (Service:string, ['201']:long, ['202']:long, ['401']:long)
[
    "A", 100, 50, 20, 
    "C", 25, 0, 0
];
T
| extend ['2xxCount'] = ['201'] + ['202'], ['4xxCount'] = ['401']

| 服务| 201 | 202 | 401 |2xxCount| 4xxCount|
| --|--|--|--|--|--|
| 一| 100 | 50 | 20 | 150 | 20 |
| C| 25 | 0 | 0 | 25 | 0 |

您应该能够通过组合使用narrow和pivot来实现这一点：

let T = datatable (Service:string, ['201']:long, ['202']:long, ['401']:long)
[
    "A", 100, 50, 20, 
    "C", 25, 0, 0
];
let categorizedData=T
| evaluate narrow()
| parse Column with "['" Code "']"
| extend Column = coalesce(Code, Column)   // strip the [' '] from the column names
| extend CodeCategory = strcat(toint(Code)/100, 'xx');
let sumByCategory=categorizedData
| where isnotempty(Code)
| summarize Value=tostring(sum(toint(Value))) by Column=CodeCategory, Row;
categorizedData
| union sumByCategory
| project-away Code, CodeCategory
| evaluate pivot(Column, take_any(Value))
| project-away Row

测试结果：
| 201 | 202 |2xx| 401 |4xx|服务|
| --|--|--|--|--|--|
| 25 | 0 | 25 | 0 | 0 |C|
| 100 | 50 | 150 | 20 | 20 |一|
唯一有点烦人的是，你不能控制pivot返回的列顺序，但是如果最大列数是固定的，你可以硬编码一个重排序，如果它对你很重要的话。