如果没有看到代码，就无法知道哪里出了问题。但我可以想象一个场景，看起来你的DESTROY（）方法没有被调用：

#!/usr/bin/perl
use strict;
use warnings;
sub DESTROY {
    die {};
    print "DESTROY\n";
}
{
    print "creating object...\n";
    my $obj = bless {};
    print "it goes out of scope...\n";
}
print "object is out of scope\n";

此脚本将打印：

creating object...
it goes out of scope...
object is out of scope

这个错误可能不像这个例子那么明显，die（）调用可能在DESTROY代码的深处。
die（）调用可能是由一些你没有想到的条件引起的。对象在全局销毁过程中以任意顺序被定义：

#!/usr/bin/perl
use strict;
use warnings;
sub DESTROY {
    die {} if ! defined $_[0]->[0];
    print "$_[0]->DESTROY()\n";
}
print "creating objects...\n";
my $x = bless [];
my $y = bless [$x];
$x->[0] = $y;
print "before global destruction...\n";

循环引用并不是必须的，一个对象检查它是否可以访问另一个对象，如果访问失败，抛出一个异常。
h2h，马蒂亚斯

还有另一种不调用DESTROY的方式，它没有特别明确的文档记录。它只会在你编写守护进程之类的时候影响你。本质上，如果你的进程因为一个信号而死亡，（即使是CTRL-C，实际上是SIGINT），那么它就不会调用DESTROY方法。你可以通过使用一个只调用exit（）的信号处理程序来让它这样做。在下面的例子中，如果程序正常退出，或者如果接收到SIGTERM，则调用DESTROY（）方法：

sub _signal_handler {
  exit(0);
}
sub new {
  my ($class) = @_;
  my $self = {};
  bless $self, $class;
  SIG{'TERM'} = \&_signal_handler;
  return $self;
}
sub DESTROY {
  my ($self) = @_;
  print "Destroy method called\n";
}

刚刚发现在一个类中有一个以上的DESTROY子也会导致这种情况，看起来只有最后一个示例被调用。

对exec的调用将不会调用Destroy：

use strict;
use warnings;
sub DESTROY {
    print "DESTROY\n"; # never runs
}
{
    print "creating object...\n";
    my $obj = bless {};
    print "it goes out of scope...but doesn't call DESTROY:\n";
    exec('/bin/true');
}
print "object is out of scope\n"; # never runs