必要的更正

mov bl,8
input:
  mov ah,07h
  int 21h
  cmp al,46
  sub al,30h
  cmp al,0
  je  valid
  cmp al,1
  je  valid
  jmp input
valid:
  cmp bl,0
  je  exit
  sub bl,1
  shl cl,1
  add cl,al
  jmp input
exit:

字符串

• cmp al,46指令没有任何用处。它是以前编辑时留下的：只需删除它。
• 输入循环运行1次太多！幸运的是，你没有把第九个输入加到CL寄存器。原因是你在错误的地方检查BL变成0。见下文。

您可以简化检查和循环：

mov  bl, 8
input:
  mov  ah, 07h   ; DOS.DirectSTDINInput
  int  21h       ; -> AL
  sub  al, 30h   ; Convert from character to number [0,9]
  cmp  al, 1     ; Everything other than [0,1] is ABOVE 1 ...
  ja   input     ; and so `JA input` will go repeat the input
  shl  cl, 1     ; Make room in CL
  add  cl, al    ; Add the new digit
  dec  bl        ; `DEC` already sets the flags
  jnz  input     ; Repeating 8 times means we jump back 7 times
exit:

exit:
  mov bl,15
  and bl,cl
  cmp bl,0
  je  printzero
  cmp bl,1
  je  printone
  ...
exit2:  
  mov bl,240
  and bl,cl
  cmp bl,0
  je  printzero2
  cmp bl,1
  je  printone2
  ...

的数据

• 您需要先显示最高有效位！因此在 exit 使用掩码240来检索高半字节，在 * exit 2 * 使用掩码15来检索低半字节。
• 您没有真正检索到高半字节！240的and所做的是从BL寄存器中删除低半字节，但高半字节仍然保留在原来的位置。这意味着BL中的值为{0，16，32，48，64，80，96，112，128，144，160，176，192，208，224，240}。

然后，* 快速修复 * 是替换cmp bl,?指令系列：

exit:
  mov  bl, 240
  and  bl, cl
  cmp  bl, 0
  je   printzero2
  cmp  bl, 16
  je   printone2
  cmp  bl, 32
  je   printtwo2
  ...
exit2:
  mov  bl, 15
  and  bl, cl
  cmp  bl, 0
  je   printzero
  cmp  bl, 1
  je   printone
  cmp  bl, 2
  je   printtwo
  ...

型

改进的第一步

目前你的程序包含很多重复的指令。更好的解决方案存在，我相信@PeterCordes提供的链接会揭示这些。
尽管如此，除了自己完成整个任务之外，我建议你学习下面的代码，你会发现这已经大大简化了程序，并且它演示了如何编写可读的代码。请注意，我并不是把它作为 * 最佳 * 解决方案：

mov  bl, 8
input:
  mov  ah, 07h   ; DOS.DirectSTDINInput
  int  21h       ; -> AL
  sub  al, '0'   ; Convert from character to number [0,9]
  cmp  al, 1     ; Everything other than [0,1] is ABOVE 1 ...
  ja   input     ; and so `JA input` will go repeat the input
  shl  cl, 1     ; Make room in CL
  add  cl, al    ; Add the new digit
  dec  bl        ; `DEC` already sets the flags
  jnz  input     ; Repeating 8 times means we jump back 7 times
; ---------------
  mov  bl, 0F0h  ; High Nibble mask
  and  bl, cl    ; BL = {0, 16, 32, 48, ... , 208, 224, 240}
  mov  dl, '0'
  cmp  bl, 0
  je   printHigh
  mov  dl, '1'
  cmp  bl, 16
  je   printHigh
  
  ...
  
  mov  dl, 'E'
  cmp  bl, 224
  je   printHigh
  mov  dl, 'F'   ; No need for `CMP BL, 240`. It's 240 for sure
printHigh:
  mov  ah, 02h
  int  21h
; ---------------
  mov  bl, 0Fh   ; Low Nibble mask
  and  bl, cl    ; BL = {0, 1, 2, 3, ... , 13, 14, 15}
  mov  dl, '0'
  cmp  bl, 0
  je   printLow
  mov  dl, '1'
  cmp  bl, 1
  je   printLow
  
  ...
  
  mov  dl, 'E'
  cmp  bl, 14
  je   printLow
  mov  dl, 'F'   ; No need for `CMP BL, 15`. It's 15 for sure
printLow:
  mov  ah, 02h
  int  21h
; ---------------
  mov  ax, 4C00h
  int  21h

型

最终改进步骤

因为你的程序包含8个从键盘输入的字符和2个输出到屏幕的字符，所以优化的版本应该关注代码大小而不是执行时间，这10个DOS函数所花费的时间几乎占了执行时间的100%！
由于所有的重复指令，你的程序目前包含471字节。我的“第一步”解决方案已经将这个数字降低到255字节，但我们肯定可以做得更好吗？
让我们看看这个程序是怎么做的，你输入八个二进制数字，合并把它们组合成一个字节大小的值，然后立即把这个字节分解成两个半字节。
通常，（相当大的）速度增益或大小减小来自于我们使用的方法的根本改变。我建议的是不必将一个字节分解为两个半字节。下面的片段重复两次，只有四个二进制数字的输入被转换为一个十六进制字符。

• 第一个代码片段使用了一个包含十六进制字符的查找表。这个解决方案的长度为55字节：

ORG 256
     call @f              ; -> DH (AX BX)
     mov  dl, dh
     call @f              ; -> DH (AX BX)
     mov  ah, 02h         ; DOS.DisplayOutput
     int  21h             ; -> (AL)
     mov  dl, dh
     int  21h             ; -> (AL)
     ret                  ; Terminate in .COM program
@@:  mov  bx, 0010h       ; Initialize BX with a sentinel-bit set at index 4
     mov  ah, 07h         ; DOS.DirectSTDINInput
@@:  int  21h             ; -> AL
     sub  al, '0'         ; Convert from ["0","1"] to [0,1]
     shr  al, 1           ; Bring digit [0,1] into the carry flag
     jnz  @b              ; Every invalid key repeats the loop
     rcl  bl, 1           ; Bring new digit into BL
     jnc  @b              ; Repeat while sentinel-bit was not shifted out
     mov  dh, [list + bx] ; Fetch a hex character
     ret
lst: db   '0123456789ABCDEF'

型

• 第二个代码片段使用了一个非常古老而又非常聪明的计算方法将[0，15]转换为十六进制字符。这个解决方案有39字节：

ORG 256
     call @f              ; -> AL (AX BX)
     xchg dx, ax          ; Shorter code than `mov dl, al`
     call @f              ; -> AL (AX BX)
     push ax
     mov  ah, 02h         ; DOS.DisplayOutput
     int  21h             ; -> (AL)
     pop  dx
     int  21h             ; -> (AL)
     ret                  ; Terminate in .COM program
@@:  mov  bl, 00010000b   ; Initialize BL with a sentinel-bit set at index 4
     mov  ah, 07h         ; DOS.DirectSTDINInput
@@:  int  21h             ; -> AL
     sub  al, '0'         ; Convert from ["0","1"] to [0,1]
     shr  al, 1           ; Bring digit [0,1] into the carry flag
     jnz  @b              ; Every invalid key repeats the loop
     rcl  bl, 1           ; Bring new digit into BL
     jnc  @b              ; Repeat while sentinel-bit was not shifted out
     xchg ax, bx          ; Shorter code than `mov al, bl`
     cmp  al, 10          ; \.
     sbb  al, 69h         ;  |. From [0,15] to {["0","9"],["A","F"]}
     das                  ;  /.
     ret                  ; AL now has a hex character

型
这些优化的片段是使用FASM组装的。