我尝试创建一个Azure VM模块，并使用它的所有其他属性，我能够成功地配置需求。
错误消息表明，您在azurerm_virtual_machine_extension资源中迭代的对象没有名为virtual_machines_name的属性。这意味着您的each.value.virtual_machines_name没有正确引用VM名称。
为了克服这个问题，我尝试了一种配置，它可以很好地与预期的相同配置和代码更改一起工作。

我的地形配置：
main.tf：

provider "azurerm" {
    features {}
}

data "azurerm_resource_group" "existing_rg" {
  name = var.resource_group_name
}

# Virtual Network and Subnet Configuration
resource "azurerm_virtual_network" "main_vnet" {
  name                = "mainvk-vnet"
  address_space       = ["10.0.0.0/16"]
  location            = var.location
  resource_group_name = data.azurerm_resource_group.existing_rg.name
}

resource "azurerm_subnet" "main_subnet" {
  name                 = "vkinternal"
  resource_group_name  = data.azurerm_resource_group.existing_rg.name
  virtual_network_name = azurerm_virtual_network.main_vnet.name
  address_prefixes     = ["10.0.1.0/24"]
}

# Network Interface Configuration
resource "azurerm_network_interface" "vm_nic" {
  for_each = var.virtual_machines

  name                = "${each.value.name}-nic"
  location            = var.location
  resource_group_name = data.azurerm_resource_group.existing_rg.name

  ip_configuration {
    name                          = "internal"
    subnet_id                     = azurerm_subnet.main_subnet.id
    private_ip_address_allocation = "Dynamic"
    # public_ip_address_id if you need public IPs
  }
}

# Virtual Machine Configuration
resource "azurerm_windows_virtual_machine" "windowsvm" {
  for_each = var.virtual_machines

  name                = each.value.name
  resource_group_name = data.azurerm_resource_group.existing_rg.name
  location            = var.location
  size                = each.value.size
  admin_username      = each.value.admin_username
  admin_password      = each.value.admin_password

  network_interface_ids = [azurerm_network_interface.vm_nic[each.key].id]

  os_disk {
    caching              = "ReadWrite"
    storage_account_type = "Standard_LRS"
    # other required configurations for os_disk
  }

    source_image_reference {
    publisher = "MicrosoftWindowsServer"
    offer     = "WindowsServer"
    sku       = "2019-Datacenter"  # Adjust the SKU as per your requirement
    version   = "latest"
  }

  # other required configurations like OS profile, etc.
}

resource "azurerm_virtual_machine_extension" "vm_extensions" {
  for_each = var.vm_extensions

  name                 = each.value.name
  virtual_machine_id   = azurerm_windows_virtual_machine.windowsvm[each.value.virtual_machine_name].id
  publisher            = "Microsoft.Compute"
  type                 = "CustomScriptExtension"
  type_handler_version = "1.10"

  settings = jsonencode({
    "fileUris"         = ["SAS_URL"],  # Replace with the actual URL of your script
    "commandToExecute" = "powershell -ExecutionPolicy Unrestricted -File powershell.ps1"
  })
}

字符串
请确保在容器blob中上传PowerShell脚本以及该PowerShell脚本的SAS_URL的相关权限。

variables.tf：

variable "virtual_machines" {
  description = "Configuration for each virtual machine"
  type = map(object({
    name             = string
    size             = string
    admin_username   = string
    admin_password   = string
  }))
}

variable "vm_extensions" {
  description = "Configuration for VM extensions"
  type = map(object({
    name                  = string
    virtual_machine_name  = string
    publisher             = string
    type                  = string
    type_handler_version  = string
  }))
}

variable "resource_group_name" {
  description = "The name of the resource group"
  type        = string
}

variable "location" {
  description = "The location/region in which to create the resources"
  type        = string
}

型

terraform.tfvars：

virtual_machines = {
  "vm1" = {
    name             = "vk-vm1"
    size             = "Standard_DS1_v2"
    admin_username   = "adminuser"
    admin_password   = "AdminPassword123!"
  },
  "vm2" = {
    name             = "vk-vm2"
    size             = "Standard_DS1_v2"
    admin_username   = "adminuser"
    admin_password   = "AdminPassword123!"
  }
}

vm_extensions = {
  "extension1" = {
    name                  = "vk-extension1"
    virtual_machine_name  = "vm1"
    publisher             = "Microsoft.Compute"
    type                  = "CustomScriptExtension"
    type_handler_version  = "1.10"
  },
  "extension2" = {
    name                  = "vk-extension2"
    virtual_machine_name  = "vm2"
    publisher             = "Microsoft.Compute"
    type                  = "CustomScriptExtension"
    type_handler_version  = "1.10"
  }
}

resource_group_name = "sakavya"
location            = "westus2"

型

输出：

的数据

的

的