要为您的Gradle 7.0+项目生成pom.xml文件，我建议您执行以下步骤：

1.在插件声明中添加maven-publish

我想你已经这么做了，但作为参考：

plugins {
    id 'java'
    id 'maven-publish'
}

字符串

2.定义发布

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            groupId = 'com.github.tcsizmadia'
            artifactId = 'gradle-sandbox'
            version = '1.0-SNAPSHOT'

            pom {
                name = 'Gradle Sandbox'
                description = 'Sandbox Project for Gradle Builds'
            }
        }
    }
}

型
请确保根据您的需要自定义（groupId、artifactId等）。

3.创建一个任务到pumpom.xml（可选）

作为一个 nice to have 特性，您可以添加一个任务来重命名和复制生成的pom.xml文件。

tasks.register('renamePom') {
    doLast {
        def pomFile = file("${layout.buildDirectory.get().asFile}/publications/mavenJava/pom-default.xml")
        if (pomFile.exists()) {
            def newPomFile = file("${layout.buildDirectory.get().asFile}/resources/main/META-INF/maven/pom.xml")
            newPomFile.getParentFile().mkdirs()
            pomFile.renameTo(newPomFile)
        }
    }
}

型
在这里，我指定了一个任务，将默认的build//publications/mavenJava/pom-default.xml复制到build/pom.xml。

4.生成pom.xml完成Build

这不是强制性的，但如果您希望在构建时生成pom.xml，请将以下内容附加到build.gradle文件中：

generatePomFileForMavenJavaPublication.finalizedBy(renamePom)
build.finalizedBy generatePomFileForMavenJavaPublication

型
如果跳过此步骤，您可以为您的项目发布生成pom.xml：

./gradlew generatePomFileForMavenJavaPublication

型

一个极简的完整示例

plugins {
    id 'java'
    id 'maven-publish'
}

group = 'com.github.tcsizmadia'
version = '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

dependencies {
    testImplementation platform('org.junit:junit-bom:5.9.1')
    testImplementation 'org.junit.jupiter:junit-jupiter'
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            groupId = 'com.github.tcsizmadia'
            artifactId = 'gradle-sandbox'
            version = '1.0-SNAPSHOT'

            pom {
                name = 'Gradle Sandbox'
                description = 'Sandbox Project for Gradle Builds'
            }
        }
    }
}

tasks.register('renamePom') {
    doLast {
        def pomFile = file("${layout.buildDirectory.get().asFile}/publications/mavenJava/pom-default.xml")
        if (pomFile.exists()) {
            def newPomFile = file("${layout.buildDirectory.get().asFile}/resources/main/META-INF/maven/pom.xml")
            newPomFile.getParentFile().mkdirs()
            pomFile.renameTo(newPomFile)
        }
    }
}

generatePomFileForMavenJavaPublication.finalizedBy(renamePom)
build.finalizedBy generatePomFileForMavenJavaPublication

型